我正在分割故障 - 组装

Question

我正在尝试汇编X86，但我得到了ZSH：分割故障./test错误。 我正在尝试自己制作一些基本图书馆，以便以后使用。它分为三个文件 - string.asm用于字符串操作，stdio.asm用于标准IO操作以及libtest.asm用于库测试。我打算添加更多功能，但我想先测试这些功能。

;;;;;;;;;;;;;;;;;
;;; stdio.asm ;;;
;;;;;;;;;;;;;;;;;
global print ; void print(string* text)
extern strlen ; int32 strlen(string* string)

section .data
stdin dd 0
stdout dd 1
stderr dd 2
newline db 0x0a, 0x00

section .text

print:
    push ebp
    mov ebp, esp
    push eax
    push ebx
    push ecx
    push edx
    
    ; get parameters
    mov ecx, dword [ebp+8]
    ; call strlen
    push ecx
    call strlen
    add esp, 4
    ; moving length
    mov ecx, eax
    ; moving syscall num and out desc
    mov eax, 4
    mov ebx, [stdout]
    ; syscall
    int 0x80
    
    pop edx
    pop ecx
    pop ebx
    pop eax
    mov esp, ebp
    pop ebp
    ret

;;;;;;;;;;;;;;;;;
;; string.asm ;;;
;;;;;;;;;;;;;;;;;
global strlen ; int32 strlen(string* str)

section .text
strlen:
    push ebp
    mov ebp, esp
    push ebx
    
    mov ebx, dword [ebp+8]
    
    mov eax, 0
    loop1:
        cmp [ebx+eax], byte 0x00
        inc eax
        jne loop1
    dec eax
    
    pop ebx
    mov esp, ebp
    pop ebp
    ret

;;;;;;;;;;;;;;;;;
;; libtest.asm ;;
;;;;;;;;;;;;;;;;;
global _start

extern print

section .data
msg db 'Hello, world!', 0x0a, 0x00

section .text
_start:
    push msg
    call print
    add esp, 4
    
    mov eax, 1
    mov ebx, 0
    int 0x80

执行：

$ nasm -f elf32 stdio.asm

$ nasm -f elf32 string.asm </

code $ nasm -f elf32 libtest.asm

$ ld -m elf_i386 -o test stdio.o string.o libtest.o

$ ./ test

我不知道该错误可能在哪里你们。

谢谢！

Answer 1

两个错误：

    ; moving length
    mov ecx, eax
    ; moving syscall num and out desc
    mov eax, 4
    mov ebx, [stdout]
    ; syscall
    int 0x80

参考，写系统调用需要ecx的缓冲指针，而edx中的长度则需要。您的长度在ecx中，缓冲指针根本没有。进行：

    mov edx, eax
    mov ecx, dword [ebp+8]
    mov eax, 4
    mov ebx, [stdout]
    int 0x80

接下来，查看：

        cmp [ebx+eax], byte 0x00
        inc eax
        jne loop1

inc指令根据其输出设置零标志。因此，您的jne不在cmp的结果上分支，而是在是否将eax递增为零上（即包裹）。因此，您的循环会迭代太多次。

jne需要立即在cmp之后，没有其他标志模拟说明。您可以通过几种方法来重写。一个是：

    mov eax, -1
loop1:
        inc eax
        cmp byte [ebx+eax], 0x00
        jne loop1

请注意，最后消除了对额外的dec eax的需求。

修复这些内容后，该程序对我有用。