如何运行将作业提交给qbatch的命令，然后获取工作号以供以后在CL PGM中使用

Question

我尝试创建一个向qbatch提交作业的命令，之后我想获得下一个命令的返回的作业编号，

我尝试rtvjoba，但这不是正确的

rtvjoba检索我当前的用户作业 当提交命令有不同的工作号码时，

请帮助我解决

我附加代码。

           PGM
           DCL        VAR(&TEMPFILE)             TYPE(*CHAR) LEN(10)
           DCL        VAR(&LEVEL)                TYPE(*CHAR) LEN(10)
           DCL        VAR(&USER )                TYPE(*CHAR) LEN(10)
           DCL        VAR(&JOB  )                TYPE(*CHAR) LEN(10)
           DCL        VAR(&NBR  )                TYPE(*CHAR) LEN(06)
           DCL        VAR(&SBMMSGQ)              TYPE(*CHAR) LEN(10)
           DCLF       FILE(MLIB/PGM_LIST)
           RTVJOBA    USER(&USER)
           RTVJOBA    NBR(&NBR )
           CHGVAR     VAR(&TEMPFILE)  VALUE(&USER || '01')
           CHKOBJ     OBJ(TEMPLIB/&TEMPFILE) OBJTYPE(*FILE)
           MONMSG     MSGID(CPF9801) +
                           EXEC(GOTO CMDLBL(NEXT1))
           DLTF       TEMPLIB/&TEMPFILE
NEXT1:       CPYF       FROMFILE(LIB/PGM_TEMP)     +
                      TOFILE(TEMPLIB/&TEMPFILE) +
                      CRTFILE(*YES)
     /*    ADDLIBLE   &LEVEL              */
           MONMSG     MSGID(CPF2110) EXEC(GOTO CMDLBL(ERRMSG1))
           MONMSG     MSGID(CPF2103)
READ:        RCVF       RCDFMT(RECORD1)
           MONMSG     MSGID(CPF0864) EXEC(GOTO CMDLBL(CLOSE))
           COBLIST    (&PGM_NAME)   LEVEL(*FULL) /* submit a job to QBATCH */                    
           RTVJOBA    NBR(&NBR)
           CPYSPLF    FILE(&PGM_NAME) TOFILE(TEMPLIB/&TEMPFILE)      +
                      JOB(&NBR/&USER/&PGM_NAME)                       +
                       MBROPT(*ADD)  SPLNBR(*LAST)
           GOTO READ
CLOSE:       CLOSE
        /* RMVLIBLE   &LEVEL    */
           GOTO RETURN
ERRMSG1:     SNDPGMMSG  MSG('LIB NOT FOUND')
           GOTO CLOSE
RETURN:      RETURN
           ENDPGM

Answer 1

SBMJOB之后，您可以收到提供提交的作业号的完成消息。您可以尝试此小程序以查看其工作原理。

     /* Data structure with the first three replacement */  
     /* values of CPC1221                               */  
     DCL        VAR(&CPC1221MSG) TYPE(*CHAR) LEN(26)        
        DCL     VAR(&jobname1) TYPE(*CHAR) STG(*DEFINED) +  
                  LEN(10) DEFVAR(&CPC1221MSG 1)             
        DCL     VAR(&jobuser2) TYPE(*CHAR) STG(*DEFINED) +  
                  LEN(10) DEFVAR(&CPC1221MSG 11)            
        DCL     VAR(&jobnum3) TYPE(*CHAR) STG(*DEFINED) +   
                  LEN(6) DEFVAR(&CPC1221MSG 21)             

     SBMJOB     CMD(DSPJOB OUTPUT(*PRINT)) JOBQ(QINTER)     
     RCVMSG     PGMQ(*SAME) MSGTYPE(*COMP) RMV(*NO) +       
                  MSGDTA(&CPC1221MSG)                       
     sndpgmmsg (&jobname1 *cat &jobuser2 *cat &jobnum3)       

          

Answer 2

我用来实现这一目标的唯一方法是使用 spawn api ，也许您应该看看它。

返回值
值 Spawn（）成功。返回的值是
子过程的过程ID。
-1 spawn（）未成功。设置了ERRNO变量以指示错误。

对不起，我无法给您举个例子，因为我使用此API制定的唯一代码是为我的公司。
但是整个想法是您可以产生多个过程并获取这些过程ID。使用此过程ID，您可以查看是否仍然处于活动状态。