使用批处理处理文本文件

Question

我是批处理脚本的新手，想与内容一起处理我的输入文件：

MD5 hash of sample.js,
81f87dd81ef88f59a57d95d9ede5f92e
MD5 hash of searchReplace.js,
3493b216e1024f0d6de417ef6c8b3962
MD5 hash of Select Anything.js,
009f2b911b50550502b87aeeeb969b55

输出应该看起来像：

MD5 hash of sample.js,81f87dd81ef88f59a57d95d9ede5f92e
MD5 hash of searchReplace.js,3493b216e1024f0d6de417ef6c8b3962
MD5 hash of Select Anything.js,009f2b911b50550502b87aeeeb969b55

 Can someone please help me out with it ?

Answer 1

尝试以下操作：

@echo off
setlocal enableDelayedExpansion
set "info_file=.\example1.txt"

for /f "useback tokens=* delims=" %%a in ("%info_file%") do (
    set "line=%%a"
    if "!line:~0,3!" EQU "MD5" (
        set "to_echo=!line!"
    ) else (
        set "to_echo=!to_echo!,!line!"
        echo !to_echo!
    )
)

endlocal

Answer 2

这起作用：

@echo off
setlocal

call :procFile < input.txt > output.txt
goto :EOF


:procFile
   set /P "line1="
   if errorlevel 1 exit /B
   set /P "line2="
   echo %line1%%line2%
goto procFile

---

您也可以通过 /f < /code>命令通过读取文件：

@echo off
setlocal EnableDelayedExpansion

set "line="
(for /F "delims=" %%a in (input.txt) do (
   if not defined line (
      set "line=%%a"
   ) else (
      echo !line!%%a
      set "line="
   )
)) > output.txt