在Excel中计数独特的值，但在VBA中给出类型不匹配错误

Question

因此，我正在尝试获得我的数据范围内有多少个唯一类别，并且知道如何在Excel中进行操作，

=SUMPRODUCT(1/COUNTIF(général!N2:N229;général!N2:N229))

但是当我尝试通过VBA使用它时，我会收到类型的不匹配错误。

 WorksheetFunction.SumProduct(1 / Application.WorksheetFunction.CountIf(Range("N2:N229"), Range("N2:N229")))

---

x4 = Worksheets("général").Cells(Rows.Count, 14).End(xlUp).Row

'x4 = 229

WorksheetFunction.SumProduct(1 / WorksheetFunction.CountIf(Range("N2:N"& x4), Range("N2:N" & x4)))

---

 WorksheetFunction.SumProduct(1 / WorksheetFunction.CountIf(Worksheets("général").Range("N2:N" & x4), Worksheets("général").Range("N2:N" & x4)))

---

有人可以帮我吗？这让我发疯了。

Answer 1

在VBA中，工作表函数的行为并不完全相同。您可以使用评估，按原样编写公式并使用范围地址。但是，更好的方法是使用scipting.dictionary。请尝试下一个代码，该代码将返回唯一值编号，但每个代码也是这些唯一值以及每个唯一值数字（在“ O：p”列中）：

Sub countUnique()
  Dim sh As Worksheet, lastR As Long, arr, i As Long, dict As Object
  
  Set sh = ActiveSheet
  lastR = sh.Range("N" & sh.rows.count).End(xlUp).row
  arr = sh.Range("N2:N" & lastR).value 'place the range in an array for  faster processing
  Set dict = CreateObject("Scripting.Dictionary")
  dict.CompareMode = TextCompare

  For i = 1 To UBound(arr)
    dict(arr(i, 1)) = dict(arr(i, 1)) + 1
  Next i
  
  Debug.Print dict.count & " unique values"
  sh.Range("O2").Resize(dict.count, 1).value = Application.Transpose(dict.Keys)
  sh.Range("P2").Resize(dict.count, 1).value = Application.Transpose(dict.items)
End Sub

evaliate工作表函数，工作表函数，请尝试下一个代码：

Sub CountUniqueEvaluate()
  Dim sh As Worksheet, lastR As Long, rng As Range
  
  Set sh = ActiveSheet
  lastR = sh.Range("N" & sh.rows.count).End(xlUp).row
  Set rng = sh.Range("N2:N" & lastR)
  
   Debug.Print Evaluate("=SUMPRODUCT(1/COUNTIF(" & rng.Address & ", " & rng.Address & "))")
End Sub