antlr算术和比较表达式语法

Question

如何将关系操作添加到我的代码中，

感谢

我的代码是

grammar denem1;  
options {    
  output=AST;    
}    

tokens {    
  ROOT;    
}

parse    
  :  stat+ EOF -> ^(ROOT stat+)    
  ;

stat    
  :  expr ';'     
  ;

expr    
  : Id Assign expr -> ^(Assign Id expr)        
  | add    
  ;

add    
  :  mult (('+' | '-')^ mult)*    
  ;

mult    
  :  atom (('*' | '/')^ atom)*    
  ;

atom
  :  Id
  |  Num
  |  '('! expr ')' !
  ;

Assign  :   '=' ;

Comment : '//' ~('\r' | '\n')* {skip();};

Id      : 'a'..'z'+;

Num     : '0'..'9'+;
    
Space   : (' ' | '\t' | '\r' | '\n')+ {skip();};

Answer 1

像这样：

...

expr    
  : Id Assign expr -> ^(Assign Id expr)
  | rel
  ;

rel
  : add (('<=' | '<' | '>=' | '>')^ add)?
  ;

add    
  : mult (('+' | '-')^ mult)*
  ;

...

如果可能的话，请使用antlr v4代替旧V3。在V4中，您可以简单地执行此操作：

stat    
 : expr ';'     
 ;

expr
 : Id Assign expr
 | '-' expr
 | expr ('*' | '/') expr
 | expr ('+' | '-') expr
 | expr ('<=' | '<' | '>=' | '>') expr
 | Id
 | Num
 | '(' expr ')'
 ;