Godot/Gdscript网格运动培训

Question

因此，我一直在使用KidsCancode的Godot教程/文档来帮助我为我正在从事的项目创建一个基于口袋妖怪的网格运动。出于所有意图和目的，我想在早期的手持式口袋妖怪游戏中创建一个与该运动系统一样接近的动作系统。

我想在开始之前添加两件事。第一，我已经喜欢Kidscancode试图教授基于网格的运动的方式，因此，虽然编码的其他方法可能更简单，例如可以在诸如此类的视频中找到的方式（

因此，首先，这是我的 player场景节点树。最重要的部分是Raycast2d和Tween节点。

这是我的主要区域2D播放器节点的代码：

extends Area2D

const tile_size = 16
export var speed = 5

var inputs = { "ui_right": Vector2.RIGHT,
            "ui_left": Vector2.LEFT,
            "ui_up": Vector2.UP,
            "ui_down": Vector2.DOWN }

func _ready():
    position = position.snapped(Vector2.ONE * tile_size/2)

func _unhandled_input(event):
    if $Tween.is_active():
        return
    for dir in inputs.keys():
        if event.is_action_pressed(dir):
            move(inputs[dir])

func move(dir):
    $RayCast2D.cast_to = inputs[dir] * tile_size
    $RayCast2D.force_raycast_update()
    if !$RayCast2D.is_colliding():
        move_tween(dir)

func move_tween(dir):
    $Tween.interpolate_property(self, "position", position,
        position + inputs[dir] * tile_size, 1.0/speed, Tween.TRANS_SINE, Tween.EASE_IN_OUT)
    $Tween.start()

快速解释，func _ready（）：将播放器捕捉到网格。 func _unhandled_input（事件）：然后检查是否发生了补间，如果没有发生，请调用func move（dir）。此功能射线播放到给定的方向输入，强制射线播放更新，如果没有静态主体在给定的方向，请调用func move_tween（dir）。最后一个功能将补间插值处理到给定的方向，并启动二元过程。就是这样。再一次，这曾经工作正常。

但是，现在，当我尝试运行此操作时，我会遇到一个错误“无效的获取索引'（0，1）'（在基础上：'dictionary'）“ where”（0，1）“基于我尝试的方向更改在游戏运行时搬进来。

在调试器码头中，在堆栈帧的下方，它在“ 22- at function; move; move” $ raycast2d.cast_to = inputs = inputs [dir] * tile_size和“ 19- at function：_unhandled_input” 移动（输入[dir]）。

网站上的代码只有以下是（dir）而不是（inputs [dir]）。但是这样做只会给我另一个错误。如果有人比我更聪明地知道发生了什么，我将非常感谢任何洞察力。谢谢 ！

Answer 1

了解问题

还可以，让我们看看。变量输入具有您的字典：

var inputs = { "ui_right": Vector2.RIGHT,
            "ui_left": Vector2.LEFT,
            "ui_up": Vector2.UP,
            "ui_down": Vector2.DOWN }

键是string，并且值为vector2。

因此，这里：

    for dir in inputs.keys():
        if event.is_action_pressed(dir):
            move(inputs[dir])

变量dir将是String。这是您所需的is_action_pressed，所以这是正确的。

和输入[dir]将是vector2。这意味着在移动中，您将vector2作为参数中。

现在，在中移动您说::

func move(dir):
    $RayCast2D.cast_to = inputs[dir] * tile_size

，但请记住，您通过的参数是vector2，input> Input的键都是字符串。因此，它在这里失败：输入[dir]。

---

使用类型类型的类似问题的预警

可以帮助您尽早确定此类问题。可悲的是，在Godot 3.x中，无法指定字典的键和值。

可以说，您可以使用c＃并使用.net dictionary＆lt; tkey，tvalue＆gt;来自system.collections.collections.generic，它可以指定键和值类型。但是，我们不是在这里谈论这些词典。

您可以用GDScript判断的是您的参数是vector2：

func move(displacement:Vector2):
    # …

或string

func move(dir:String):
    # …

godot可以告诉当您用错误的参数调用它们时。

---

另一件事将有所帮助。尽管它更多地在纪律方面，但要保持一致的名称。如果您使用的名称在您的系统中具有具体的含义，它们将为您提供帮助。

例如，您调用移动这样：

move(inputs[dir])

这意味着您所传递的内容不称为dir※。但是您的移动按这样的定义：

func move(dir):
    # …

移动期望您称之为dir。您会看到，当您键入MOVE的调用时。

※：我会说您正在传递Inputs的值之一，因此所传递的内容称为Input。或者，您可以将它们称为Action，鉴于您在is_action_pressed中使用它们。同样，这将以帮助您的方式使用名称。

---

解决问题的

方法是通过使用字符串和inputs in _UNHANDLED_INPUT仅使用带有输入）。并从那里使用vector2。这意味着：

• 如果将来您想要一个不是来自其中一个输入的运动，其他方法也将很有用。
• 您没有重复在dictionary中查找的努力。

诚然，对于您的游戏来说，这些并不重要。最终，您要做的就是取决于您。但是，请考虑将这种方法提交您的考虑。

这是代码（我添加了一些类型的注释）：

extends Area2D

const tile_size:float = 16
export var speed:float = 5

var inputs = { "ui_right": Vector2.RIGHT,
            "ui_left": Vector2.LEFT,
            "ui_up": Vector2.UP,
            "ui_down": Vector2.DOWN }

func _ready():
    position = position.snapped(Vector2.ONE * tile_size/2)

func _unhandled_input(event:InputEvent) -> void:
    if $Tween.is_active():
        return
    for dir in inputs.keys():
        if event.is_action_pressed(dir):
            move(inputs[dir])

func move(displacement:Vector2) -> void:
    $RayCast2D.cast_to = displacement * tile_size
    $RayCast2D.force_raycast_update()
    if !$RayCast2D.is_colliding():
        move_tween(displacement)

func move_tween(displacement:Vector2) -> void:
    $Tween.interpolate_property(self, "position", position,
        position + displacement * tile_size, 1.0/speed, Tween.TRANS_SINE, Tween.EASE_IN_OUT)
    $Tween.start()

或者您可以每次都使用String思考并查询字典。我相信，这是您的意图。像这样：

extends Area2D

const tile_size:float = 16
export var speed:float = 5

var inputs = { "ui_right": Vector2.RIGHT,
            "ui_left": Vector2.LEFT,
            "ui_up": Vector2.UP,
            "ui_down": Vector2.DOWN }

func _ready():
    position = position.snapped(Vector2.ONE * tile_size/2)

func _unhandled_input(event:InputEvent) -> void:
    if $Tween.is_active():
        return
    for dir in inputs.keys():
        if event.is_action_pressed(dir):
            move(dir)

func move(dir:String) -> void:
    $RayCast2D.cast_to = input[dir] * tile_size
    $RayCast2D.force_raycast_update()
    if !$RayCast2D.is_colliding():
        move_tween(dir)

func move_tween(dir:String) -> void:
    $Tween.interpolate_property(self, "position", position,
        position + input[dir] * tile_size, 1.0/speed, Tween.TRANS_SINE, Tween.EASE_IN_OUT)
    $Tween.start()

请注意，_unhandled_input将dir传递给移动。 移动的方式相同，将dir传递给move_tween。