Erlang地图密钥模式匹配

Question

我对Erlang更新，我有一个像＃{“ a/。+”：“ v1”，“ b/c/+”：“ v2”}的地图，

我想通过输入键获得值“匹配” A /.+”并获取“ V1”。

当键确切的时，并且输入密钥是正则是REGEX，我该如何实现它。

Answer 1

在这种情况下，您 必须使用地图。这个想法是使用Regex查找与输入的关键匹配，然后返回映射的值。
非优化版本正在使用re：run/2而无需编译模式。

L1 = [{"a/.+", "v1"}, {"b/c/.+", "v2"}],
LResult1 = lists:foldl(fun({K, V}, ListIn) ->  
            Match = re:run("a/d", K),
            case Match of
                nomatch -> ListIn;
                      _ -> ListIn ++ [{K, V}]
            end
        end,
        [],
        L1
        ),
case LResult1 of
    [] -> 
        no_matching_rule;
     _ -> 
        Hd1 = hd(LResult1),
        {K1, V1} = Hd1,
        V1
end.

优化的版本可以通过在使用之前对正则态度图案进行编译。

{ok, Mp1} = re:compile("a/.+"),
{ok, Mp2} = re:compile("b/c/.+"),
L2 = [{Mp1, "v1"}, {Mp2, "v2"}],
LResult2 = lists:foldl(fun({K, V}, ListIn) ->  
            Match = re:run("a/d", K),
            case Match of
                nomatch -> ListIn;
                      _ -> ListIn ++ [{K, V}]
            end
        end,
        [],
        L2
        ),
case LResult2 of
    [] -> 
        no_matching_rule;
     _ -> 
        Hd2 = hd(LResult2),
        {K2, V2} = Hd2,
        V2
end.

在Erlang Shell中粘贴上述任何代码都会产生“ V1”。

上面的代码假定一个输入可以具有多个匹配的模式，但是只有第一个输入将作为输出打印。

Answer 2

如果要在地图中找到与字符串匹配的所有键，则需要在整个地图上迭代：

a.erl：

-module(a).
-compile(export_all).

find(String, Map) ->
    MyMatchFun = fun (RegexKey, Val, Acc) -> 
                         case re:run(String, RegexKey) of
                             nomatch -> Acc;
                             {match, _} -> [Val | Acc]
                         end
                 end,
    maps:fold(MyMatchFun, _Acc=[], Map).

在shell中：

34> c(a).              
a.erl:2:2: Warning: export_all flag enabled - all functions will be exported
%    2| -compile(export_all).
%     |  ^

{ok,a}

35> Map.
#{"a/.+" => "v1","a/b/.+" => "v3","b/c/.+" => "v2"}

36> a:find("a/d", Map).
["v1"]

36> a:find("b/c/dd", Map).
["v2"]

38> a:find("a/b/cc", Map).
["v3","v1"]

如果地图中只有一个键可以匹配您的字符串，则找到匹配项后，您可以在地图上停止迭代：

a.erl：

-module(a).
-compile(export_all).

find(String, Map) ->
    I = maps:iterator(Map),
    match_for(String, I).

match_for(String, I) ->
    case maps:next(I) of 
        none ->  %% then you have reached the end of the Map
            no_keys_in_map_matched_string;

        {RegExKey, Val, NewI} ->
            case re:run(String, RegExKey) of
                nomatch -> match_for(String, NewI);  %% continue iterating over the Map looking for a match
                {match, _} -> Val   %% found a match, so return the associated value
            end
    end.

在外壳中：

27> c(a).                
a.erl:2:2: Warning: export_all flag enabled - all functions will be exported
%    2| -compile(export_all).
%     |  ^

{ok,a}

28> Map = #{"a/.+" => "v1", "b/c/.+" => "v2"}.

29> a:find("a/d", Map).                                         
"v1"

30> a:find("a/b/cc", Map).
"v1"

31> a:find("b/c/dd", Map).
"v2"

32> a:find("z", Map).     
no_keys_in_map_matched_string