mysql vba连接字符串带有“ no_date_overflow”

Question

因此，我在MS Access中使用MySQL链接表有这个问题： 当我手动设置使用“禁用日期溢出错误”的ODBC Unicode连接时，我可以使用MS Access前端删除MySQL链接表中的记录。 mysql odbc设置 但是，当我使用vba中的以下连接字符串连接时，表已连接，但是当我在日期字段中输入日期或尝试删除记录时，我会得到日期溢出错误

''-------------------------------------
strConn = "Driver={" & MysqlDriver & "}" & _
           ";server=" & ServerName & _
           ";Database=" & DatabaseName & _
           ";Trusted_Connection=Yes" & _
           ";NO_DATE_OVERFLOW=1" & _  'This is the part that I think it doesn't work in the code
           ";charset=utf8" & _
           ";user=" & ConnUserName & _
           ";password=" & ConnPassword

Delete_ALL_TABLES   '' Delete All the old tables before the import
Conn.Open strConn
Debug.Print Conn.ConnectionString
Set TablesSchema = Conn.OpenSchema(adSchemaTables)
Debug.Print TablesSchema.RecordCount
Do While Not TablesSchema.EOF
 R = R + 1
 def_str = TablesSchema("TABLE_NAME")
 Debug.Print R, def_str
 Set tdfLink = db.CreateTableDef(def_str)
 tdfLink.SourceTableName = def_str
 tdfLink.Connect = "ODBC;" & strConn
 db.TableDefs.Append tdfLink
 DoEvents
 TablesSchema.MoveNext
Loop
''-------------------------------------

​

它仅与我手动创建的ODBC一起使用“禁用日期溢出错误”。

您能帮我解决连接字符串的问题吗？

如果我可以将密码保存在连接字符串中，则Bouns会有所帮助，因此当MS Access前端关闭并重新打开时，我不必导入表。

先感谢您 ：）

Answer 1

让我们从奖金开始。 MS Access有一个无证件连接池。如果创建连接，然后尝试访问同一服务器＆amp;使用相同的ODBC驱动程序主版本的数据库，即使您试图使用不同的凭据。
也将重复使用该连接。
副作用：如果您在链接表中的服务器和数据库中创建DAO连接，则它们将在不提示用户和密码的情况下工作。

同样，从安全的角度来看，可以将链接的表从ACCDE文件导入到可编辑的ACCDB中，因此最好保存没有用户＆amp;密码，并在启动时提示用户获得凭据。一个不太安全的变化是将连接字符串隐藏在VBA函数中时，然后分发ACCDE文件。因此，攻击者必须拆卸ACCDE文件才能获取密码。可以做到，但它停止了大多数非专业人士。

因此，我的建议是创建一个启动功能，Wich试图使用列表中的所有ODBC驱动程序创建连接，直到找到一个驱动程序，而不是relinks tables＆amp;仅当驾驶员已更改时，Passstrough查询。

我正在使用它来重新链接表：（与no_date_overflow一起使用）

Private Sub dsnless_table2(Name As String, strconn As String, Optional srcname As String = "", Optional myflags As Long = 0)
'
On Error GoTo myerr
ERT = "dsnless_table2"
ert2 = ert2 & " ->" & ERT
ert3 = ""

   Dim tdef As New TableDef, sourcename As String, mysource As String, db As DAO.Database, eflag As Boolean, oldcon As String
   Set db = CurrentDb
   
eflag = False
On Error Resume Next
   If IsObject(db.TableDefs(Name)) = True Then eflag = True
   If err.Number <> 0 Then eflag = False
err.Clear
On Error GoTo myerr

If eflag = True Then
   sourcename = db.TableDefs(Name).SourceTableName
   oldcon = db.TableDefs(Name).Connect
   
   If compdiff(oldcon, strconn) = False And compdiff(sourcename, srcname) = False Then GoTo skip ' .Connect, .Name and .SourcetableName is equal to new value..
   ' else: recreate table; .Connect is write protected(?) after tabledefs.append
   DoCmd.DeleteObject acTable, Name
   db.TableDefs.Refresh
Else
   sourcename = ""
End If
      
   If Len(srcname) = 0 Then
      If Len(sourcename) > 0 Then
         mysource = sourcename
      Else
         mysource = Name
      End If
   Else
      mysource = srcname
   End If
   
   Set tdef = db.CreateTableDef(Name, 0, mysource, strconn)  
   db.TableDefs.Append tdef  

' db.TableDefs.Append stores actual connection string instead of the specified one. 
   If tdef.Connect <> strconn Then
      tdef.Connect = strconn
      tdef.RefreshLink
   End If
   
skip:
On Error Resume Next
db.TableDefs(Trim(Name)).Properties("Attributes").Value = myflags ' dbHiddenObject ' 536870913  ' dbsystemobject = -2147483646
err.Clear
On Error GoTo myerr
   
   'db.TableDefs.Refresh
   
Exit Sub
'Resume Next
myerr:
    Call show_ert(err.Number, erl)
   
End Sub




Public Function compdiff(inA As Variant, inB As Variant) As Boolean
' returns true if values doesn't match, Including Null <>2 etc.. ' Null,Null --> False.  Null, 1 --> True. 1,1 --> False. A,B --> True.
'input: anything if "=" has a meaning for that datatype.
On Error GoTo myerr

Dim OneNullflag As Boolean, Compflag As Boolean
OneNullflag = IsNull(inA) Xor IsNull(inB) 'csak az egyik Null?
Compflag = Not (IsNull(inA) Or IsNull(inB)) 'egyik sem Null?

If OneNullflag = True Then
   compdiff = True ' Null <> 2
Else
   If Compflag = True Then
      ' No Nulls
      If inA = inB Then
         compdiff = False ' 1=1 ; (1<>1) = False
      Else
         compdiff = True ' 1<>2
      End If
   Else
      compdiff = False ' Null = Null
   End If
End If

Exit Function
myerr:
   ERT = "compdiff()"
   ert2 = ert2 & " ->" & ERT
   ert3 = ""
   Call show_ert(err.Number, erl)
End Function  

，这是创建连接的函数：

Private Function dsntest(strCnn1 As Variant) As Boolean
' used by cnn_startup()
On Error GoTo myerr

   dsntest = False
   If IsNull(strCnn1) Then Exit Function
   If Len(CStr(strCnn1)) < 2 Then Exit Function

Dim dbs As DAO.Database, qdf As DAO.QueryDef, rn As Long

   Set dbs = CurrentDb()
   Set qdf = dbs.CreateQueryDef("")
   
   qdf.ReturnsRecords = False
   qdf.Connect = strCnn1
   'Any VALID SQL statement that runs on server will work below.
   qdf.SQL = "Select 0;" '"SET @icon = 1;" ' doesn't run on Oracle server --> sqlstr parameter
   
   On Error Resume Next
     qdf.Execute
     rn = err.Number
   On Error GoTo myerr
   
   If rn = 0 Then dsntest = True

cleanup:
   Set qdf = Nothing
   Set dbs = Nothing
   
   Exit Function
   
myerr:
   dsntest = False
   ERT = "dsntest"
   ert2 = ert2 & " ->" & ERT
   ert3 = ""
   Call show_ert(err.Number, erl)
   GoTo cleanup
End Function

我们基本上创建一个passstrough Query WICH可以打开连接，而不是我们将其丢弃，因此不会与任何保存的查询有关密码。

奖励信息：我建议使用ODBC驱动程序版本8.0.26。 8.0.29可能与no_date_overflow一起使用= 1。有关更多详细信息，请参阅此信息： https://bugs.mysql.com/bug.php.php.php？ id = 107235 。 0.27和0.28具有其他与访问相关的错误。

奖励信息2：MS Access VBA有一个记录的ERL对象的中途。我有一个在发布过程中运行的行编号功能。如果在编号的VBA线上发生错误，则将其存储在ERL中，直到您离开子/功能或清除错误。 Show_ert（）将一些遥测数据（包括ERL）发送到服务器，因此我可以监视客户端错误。