需要帮助将Pinescript V2转换为版本5

Question

我通过图表艺术找到了这段代码。我正在制定自己的策略，我会喜欢我自己的这个功能。它为我的入场信号提供了更好的确认。我正在尝试自己学习 pinescript，但我认为如果我学习 pinescript v2 和 v5 将花费大量时间和精力，所以我请求一些帮助将其转换为 V5，然后我可以继续改进代码。我真的很感激任何帮助。预先感谢大家。

//@version=2

threshold = input(title="Price Difference Threshold", type=float, defval=0, step=0.001)

getDiff() =>
    yesterday=security(tickerid, 'D', close[1])
    today=security(tickerid, 'D', close)
    delta=today-yesterday
    percentage=delta/yesterday
    
closeDiff = getDiff()
 
buying = closeDiff > threshold ? true : closeDiff < -threshold ? false : buying[1]

hline(0, title="zero line")

bgcolor(buying ? #3399FF : #FFFFFF , transp=1)
plot(closeDiff, color=silver, style=area, transp=75)
plot(closeDiff, color=aqua, title="prediction")

longCondition = buying
if (longCondition)
    strategy.entry("Long", strategy.long)
    
shortCondition = buying != true
if (shortCondition)
    strategy.entry("Short", strategy.short)

Answer 1

直接v2 - ＆gt; V5转换看起来像这样：

//@version=5
strategy("")
threshold = input.float(title="Price Difference Threshold", defval=0, step=0.001)

getDiff() =>
    yesterday=request.security(syminfo.tickerid, 'D', close[1], lookahead=barmerge.lookahead_on)
    today=request.security(syminfo.tickerid, 'D', close, lookahead=barmerge.lookahead_on)
    delta=today-yesterday
    percentage=delta/yesterday
    
closeDiff = getDiff()

bool buying = na 
buying := closeDiff > threshold ? true : closeDiff < -threshold ? false : buying[1]

hline(0, title="zero line")

bgcolor(buying ? #3399FF : #FFFFFF , transp=1)
plot(closeDiff, color=color.new(color.silver, 75), style=plot.style_area)
plot(closeDiff, color=color.aqua, title="prediction")

longCondition = buying
if (longCondition)
    strategy.entry("Long", strategy.long)
    
shortCondition = buying != true
if (shortCondition)
    strategy.entry("Short", strategy.short)

请注意，脚本使用security（）函数从“ D”时间范围请求数据，这允许它可以展望未来并在实时图表上进行栏的值（更多信息在这里）。这是在新脚本中皱眉的。为避免这种情况，应使用Barmerge.loohakead_off（默认情况下，在V3 -V5中默认打开）。在下面的脚本中，我更改了它，因此结果将与原始脚本有所不同，但是它是最好的，因为原始脚本运行的数据应该无法访问：

//@version=5
strategy("")
threshold = input.float(title="Price Difference Threshold", defval=0, step=0.001)

getDiff() =>
    [today, yesterday] = request.security(syminfo.tickerid, 'D', [close, close[1]], lookahead=barmerge.lookahead_off)
    delta = today - yesterday
    percentage = delta / yesterday
    
closeDiff = getDiff()

bool buying = na 
buying := closeDiff > threshold ? true : closeDiff < -threshold ? false : buying[1]

hline(0, title="zero line")

bgcolor(buying ? color.new(#3399FF, 1) : color.new(#FFFFFF, 1))
plot(closeDiff, color=color.new(color.silver, 75), style=plot.style_area)
plot(closeDiff, color=color.aqua, title="prediction")

longCondition = buying
if (longCondition)
    strategy.entry("Long", strategy.long)
    
shortCondition = buying != true
if (shortCondition)
    strategy.entry("Short", strategy.short)