我想在脚本中做一个下拉列表容器

Question

我想创建一个下拉容器来组织我的导出变量。是否可以在脚本中创建自定义下拉列表容器？

这样：

Answer 1

这是执行此操作的另一种方法。它还要求脚本是 工具< /a>.

我们需要这种方法作为要分组的变量的公共前缀。优点是我们不需要 _get 和 _set：

tool
extends Node

var custom_position:Vector2
var custom_rotation_degrees:float
var custom_scale:Vector2

func _get_property_list():
    return [
        {
            name = "Custom",
            type = TYPE_NIL,
            hint_string = "custom_",
            usage = PROPERTY_USAGE_GROUP
        },
        {
            name = "custom_position",
            type = TYPE_VECTOR2
        },
        {
            name = "custom_rotation_degrees",
            type = TYPE_REAL
        },
        {
            name = "custom_scale",
            type = TYPE_VECTOR2
        }
    ]

如您所见，我们定义了一个带有 name 的类别，该类别将出现在检查器面板，hint_string 是我们将使用的前缀。将类别放在数组中的属性之前很重要。

请参阅：添加脚本类别

附录：使用PROPERTY_USAGE_CATEGORY将生成一个命名标头，类似于图片上显示“Node2D”的标头关于这个问题。使用 PROPERTY_USAGE_GROUP 创建可折叠组。

Answer 2

是的，您可以做到这一点，但是（我认为）这有点丑陋，并缩短了您的脚本。您需要将脚本标记为工具脚本，并覆盖_get，_SET _SET 和_get_property_list函数。

一个基于您的屏幕截图的示例（不是100％确定这完全可以正常工作；我还基于一个最近的项目，此后我将其删除并在某种程度上重组了项目/代码/节点，因为略带UI' t值得脚本中的其他混乱）：

tool
extends Node2D

# Note that these are NOT exported
var actual_position: Vector2
var actual_rotation: float
var actual_scale: Vector2

# Function to enumerate the properties to list in the editor
#  - Not actually directly/automatically backed by variables
#  - Note the naming pattern - it is {group heading}/{variable}
func _get_property_list():
    var props = []
    props.append({name="transform/position", type=TYPE_VECTOR2})
    props.append({name="transform/rotation deg", type=TYPE_FLOAT}) # might not exist; look at docs to determine appropriate type hints for your properties
    props.append({name="transform/scale", type=TYPE_VECTOR2})
    return props


# Now the get/set functions to map the names shown in the editor to actual script variables
# Property names as input here will match what is displayed in the editor (what is enumerated in _get_property_list); just get/set the appropriate actual variable based on that
func _get(property: String):
    if property == "transform/position":
        return actual_position
    if property == "transform/rotation deg":
        return actual_rotation
    if property == "transform/scale":
        return actual_scale

func _set(property: String, value):
    if property == "transform/position":
        actual_position = value
        return true
    if property == "transform/rotation deg":
        actual_rotation = value
        return true
    if property == "transform/scale":
        actual_scale = value
        return true
    # Not a supported property
    return false

请注意，此答案基于Godot 3.4。我不确定Godot 4中是否可以（或将）使用更简单的方法。