调用该参数时如何更改函数？

Question

我想创建一个可以生成两个球以不同速度上升的函数。我使用了称为更改的速度的参数，以及其x坐标的另一个参数，称为x，以免它们源自同一位置。这是一个处理中的代码，因此内置了椭圆，大小，填充，笔触，设置和DRAW功能。

如果我调用该功能，则可以正常工作，并且球根据我设置的速度移动。但是，如果我两次调用risingball（）功能，则会生成两个球，但两者都以第二个执行的函数调用的速度移动。在这种情况下，在x坐标150和450处产生了两个球。第一个球应该以速度y-10移动，第二个球以速度y-5 移动。 >，但两者都以y-5移动。

因此，它们移动了，但是使其更改的代码的全部目的行不通。

void setup(){
  size(600,600);
}
float y = 600;

 void risingball(float change, float x){
  noStroke();
  fill(30,0,30);
  y = y-change;
  ellipse(x,y, 50,50);
}
  void draw(){
  background(255);
  risingball(10, 450);
  risingball(5, 250);
}

Answer 1

即使您使用函数两次，该函数也会修改相同的一个 y变量：

risingball(10, 450); // modifies y first
risingball(5, 250);  // modifies the same y again (when it shouldn't)

因为您想以独立的速度移动两个球大家都需要两个独立的y变量（每个球一个）。

您可以使用两个独立的y变量，但还需要修改该函数，以免更改相同的数据。一个选项可能是使用AY参数并返回修改后的数据：

float y1 = 600;
float y2 = 600;

void setup(){
  size(600,600);
}

 float risingball(float change, float x, float y){
  noStroke();
  fill(30,0,30);
  y = y-change;
  ellipse(x,y, 50,50);
  return y;
}
  void draw(){
  background(255);
  y1 = risingball(10, 450, y1);
  y2 = risingball(5, 250, y2);
}

另一个变体可能是简单地使用该函数渲染球，但请保留y变量更新功能外部的更新：

float y1 = 600;
float y2 = 600;

void setup(){
  size(600,600);
}

 void risingball(float x, float y){
  noStroke();
  fill(30,0,30);
  ellipse(x,y, 50,50);
}
  void draw(){
  // update data
  y1 = y1 - 10;
  y2 = y2 - 5;
  //render
  background(255);
  risingball(450, y1);
  risingball(250, y2);
}

另一个选项是使用类，尽管我不确定您是否有机会玩这些。万一：

// RisingBall(float argX, float argY, float argChange, float argSize)
RisingBall ball1 = new RisingBall(450, 600, -10, 50);
RisingBall ball2 = new RisingBall(250, 600, -5, 50);

void setup(){
  size(600,600);
  noStroke();
  fill(30,0,30);
  
}

void draw(){
  background(255);
  ball1.updateAndDraw();
  ball2.updateAndDraw();
}

class RisingBall{
  
  float x;
  float y;
  float vy;
  
  float diameter;
  
  RisingBall(float argX, float argY, float argChange, float argSize){
    x = argX;
    y = argY;
    vy = argChange;
    diameter = argSize;
  }
  
  void updateAndDraw(){
    // update
    y += vy;
    // optional: reset Y
    if(y < -diameter){
      y = height;
    }
    // draw
    ellipse(x, y, diameter, diameter);
  }
  
}