SolidWorks API（VBA）将字符串存储在数组中

Question

我想以数组的形式存储尺寸名称（字符串），以便我可以将另一个数组（尺寸名）与当前进行比较。

Public Sub WhateverName

    Dim swApp As SldWorks.SldWorks
    Dim swModel As ModelDoc2
    Dim swPart As PartDoc
    Dim swFeat As Feature
    Dim swDispDim As DisplayDimension
    Dim swDim As Dimension
    Dim vDimVals As Variant
    Dim swDimInfoNameArr As Variant
    Dim SKETCH_NAME As String
    Dim i As Variant
    Dim swDimName As Variant
    Dim swDispDimname As String
    
    Set swApp = Application.SldWorks
    Set swModel = swApp.ActiveDoc
    Set swPart = swModel
    SKETCH_NAME = "ISO Standard"
    Set swFeat = swPart.FeatureByName(SKETCH_NAME)
    Set swDispDim = swFeat.GetFirstDisplayDimension
        
        Do While Not swDispDim Is Nothing
            i = 0
            'For i = 0 To 4
            Set swDim = swDispDim.GetDimension2(Empty)
            vDimVals = swDim.GetValue3(swThisConfiguration, Empty)
           
            Debug.Print swDim.Name & "@" & SKETCH_NAME & ": " & Round(vDimVals(0), 6)
            Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
            swDimName = swDim.Name
            swDimInfoNameArr(i) = swDimName 'swModel.GetCustomInfoNames2     --> ERROR
            i = i + 1
            'Next
        Loop

End Sub

第27行正在抛出错误“类型不匹配”

Answer 1

您需要声明数组的大小，或使用其他对象存储。像词典一样：

Option Explicit
Sub main()

Dim swApp As SldWorks.SldWorks
Dim swModel As ModelDoc2
Dim swPart As PartDoc
Dim swFeat As Feature
Dim swDispDim As DisplayDimension
Dim swDim As Dimension
Dim vDimVals As Variant
Dim SKETCH_NAME As String
Dim dict As Object
Set dict = CreateObject("Scripting.Dictionary")

Set swApp = Application.SldWorks
Set swModel = swApp.ActiveDoc
Set swPart = swModel
SKETCH_NAME = "ISO Standard"
Set swFeat = swPart.FeatureByName(SKETCH_NAME)
Set swDispDim = swFeat.GetFirstDisplayDimension
 
    Do While Not swDispDim Is Nothing
        Set swDim = swDispDim.GetDimension2(Empty)
        vDimVals = swDim.GetValue3(swThisConfiguration, Empty)
        Set swDispDim = swFeat.GetNextDisplayDimension(swDispDim)
        dict.Add swDim.Name, Round(vDimVals(0), 6)
        
        Debug.Print dict.keys()(dict.Count - 1) & "@" & SKETCH_NAME & ": " & dict.Items()(dict.Count - 1)
    Loop
End Sub