如何通过pci能力id识别设备

Question

如何通过PCI功能ID识别设备？ 这是我的代码：

我尝试访问34h并检查第一个循环中的功能ID是否存在 如果存在，它指向下一个指针，但是在获取指针并放置地址的步骤中似乎存在一些问题。

'''

    push eax
    push edi
    push esi

    mov cx,100
    
    ;mov edi,[esi]      
    add edi,52     ;access 34h
    
lopreg:     
    mov eax,edi    ;read
    mov dx,0cf8h
    out dx,eax
    mov dx,0cfch
    in eax,dx
   
    cmp cx,100    ;first time 
    je first
    
    cmp ah,10
    jne nextreg
    jmp ispcie
    
first:
    cmp ah,0
    je  ending
    sub edi,52
    movzx bx,ah
    add di,bx

    loop lopreg
    jmp ending
    
ispcie:
    call set_cur        
    mov ah,09h
    lea dx,regmem        ;print pcie
    int 21h
    jmp ending
    
nextreg:
    cmp al,0
    je ending
    movzx bx,al ;
    add di,bx
    loop lopreg
ending: 
    pop esi
    pop edi
    pop eax
    ret

'''

Answer 1

这个答案是在假设该代码正在寻找 PCI Express 功能的情况下编写的。

这段代码有几个问题。

1. 在first标签处，应该使用al而不是ah来确定第一个能力的偏移量。
2. PCI Express 功能的功能 ID 是 10h，而不是 10。
3. 读取每个功能标头后，al 包含功能 id，ah 包含下一个指针。所以 cmp ah, 10 应该是 cmp al, 10h 。
4. 在 nextreg 标签处，应该使用 ah 而不是 al 来确定下一个功能的偏移量。
5. 在每次迭代中，它都会将 bx 添加到 di 中，而不删除先前的偏移量。
6. 目前尚不清楚 edi 被初始化为什么，但如果它没有设置位 31，那么此代码根本不会读取 PCI 配置空间。

这应该可行：

    mov cx,100
    
    ;mov edi,[esi]      
    add edi,52     ;access 34h
    
lopreg:     
    mov eax,edi    ;read
    mov dx,0cf8h
    out dx,eax
    mov dx,0cfch
    in eax,dx
   
    cmp cx,100    ;first time 
    je first
    
    cmp al,10h
    jne nextreg
    jmp ispcie
    
first:
    cmp al,0
    je  ending
    sub edi,52
    movzx bx,al
    add di,bx

    loop lopreg
    jmp ending
    
ispcie:
    call set_cur        
    mov ah,09h
    lea dx,regmem        ;print pcie
    int 21h
    jmp ending
    
nextreg:
    cmp ah,0
    je ending
    sub di, bx
    movzx bx,ah
    add di,bx
    loop lopreg

ending:

7. 更好的方法是将原始地址保留在 edi 中而不更改它，并为每个新偏移量使用 lea eax, [edi+ebx] .

8. 没有必要使用ecx作为循环计数器，而且逻辑有点复杂。可以将其拉直一点，以便更清晰地流动。

这是我的编写方式：（

    lea eax,[edi+34h]     
    mov dx,0cf8h
    out dx,eax
    mov dx,0cfch
    in al,dx              ; read offset of first capability
    cmp al,0
    je ending
    movzx ebx,al

lopreg:     
    lea eax,[edi+ebx]     ; offset of next capability is in ebx
    mov dx,0cf8h
    out dx,eax
    mov dx,0cfch
    in eax,dx             ; read capability header

    cmp al,10h            ; check if it is the PCI Express capability
    je ispcie

nextreg:
    cmp ah,0              ; check if it is the end of the capability list
    je ending
    movzx ebx, ah         ; set up ebx with the offset of the next capability
    jmp lopreg

ispcie:
    ; base of device PCI config space is in edi
    ; offset of PCI Express Capability is in ebx
    ...

ending:

我不知道 set_cur 和 regmem 是什么，所以我没有尝试编写这部分代码。）