如何在运行时移动由鼠标控制的TPanel？

Question

我想在运行时使用 Delphi 10.4.2 和 FMX 通过鼠标将 TPanel 移动到另一个 TPanel 上。我尝试了 OnMouseDown、OnMouseMove 和 OnMouseUp 事件。但尚不清楚事件中X和Y值的内容是什么。文档说它们是屏幕坐标。相对于屏幕、窗体、父控件还是控件本身？如何解决TPanel的移动问题？

Answer 1

文档说它们是屏幕坐标。

不，事实并非如此。 FMX.Types.TMouseEvent 和 FMX.Types.TMouseMoveEvent
文档都说：

X 和 Y - 鼠标指针在控件工作区内的像素坐标。

如何解决TPanel的移动问题？

像这样：

var
  LastPt: TPointF;
  Dragging: Boolean = False;

procedure TMyForm.PanelToDragMouseDown(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Single);
begin
  if Button = TMouseButton.mbLeft then
  begin
    LastPt := TPointF.Create(X, Y);
    Dragging := True;
  end;
end;

procedure TMyForm.PanelToDragMouseUp(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Single);
begin
  if Button = TMouseButton.mbLeft then
    Dragging := False;
end;

procedure TMyForm.PanelToDragMouseMove(Sender: TObject;
  Shift: TShiftState; X, Y: Single);
var
  CurrPt: TPointF;
begin
  if Dragging then
  begin
    CurrPt := TPointF.Create(X, Y);
    PanelToDrag.Position.Point := PanelToDrag.Position.Point + (CurrPt - LastPt);
    LastPt := CurrPt;
  end;
end;

基本上，当鼠标在面板上移动时，代码只是计算鼠标从最后一个已知位置移动到当前位置的偏移量，然后将该偏移量应用到面板的当前位置 code> 在其 Parent 中。