AWK - 比较两个 1 列文件中的匹配字符串，然后写入包含更新信息的文件

Question

我在比较两个不同编号的文件时遇到问题。行并使用文件中的信息来更新另一个文件。我尝试了在网上找到的各种关键示例，但似乎都不起作用。

希望你能帮我解决这个问题。

我有两个文件：

$ cat 1.txt
>01234
NNNNNNNNAAAAAANNNNNNAAAAANNNNAAAAANNNNAA
>17321
SSSSSSKKKKKKLLLLLIIIIIIMMMMMMNNNNNNAAAA
>13920
ZZZZZZZYYYYYYYAAAAAAABBBBBBBCCCCNNNNNNNNNN
...
...
(>1000 lines)


$ cat 2.txt
hbcd/efgh/z-01234/2000
hbcd/efgh/zw-11000/2000
hbcd/efgh/t-13290/2000
...
...
(<1000 lines)

我的目的是拥有一个更新的文件 1.txt，其中包含更新的行，但也保留文件 2.txt 中不匹配的行，所以可以保存为新文件，如下所示：

$ cat 3.txt
>abcd/efgh/z-01234/2000
NNNNNNNNAAAAAANNNNNNAAAAANNNNAAAAANNNNAA
>17321
SSSSSSKKKKKKLLLLLIIIIIIMMMMMMNNNNNNAAAA
>abcd/efgh/t-13290/2000
ZZZZZZZYYYYYYYAAAAAAABBBBBBBCCCCNNNNNNNNNN
...
...

我尝试过这样的操作： awk 'NR==FNR{a[$0]=$0;next}{a[$1]=$0}END{for (i in a) print a[i]}' 1.txt 2.txt > 3.txt

或类似这样（根据 1.txt 中的子字符串进行搜索）： awk 'NR==FNR{a[substr($0,2,5)]=$0;next}{a[$1]=$0}END{for (i in a) print a[i]}' 2.txt 1 .txt> 3.txt

但我在输出文件中得到了混淆的行，如下所示（或者甚至没有分别来自 2.txt 的行）：

01234 17321 SSSSSSKKKKKKLLLIIIMMMMMMNNNNNNNAAAA abcd/efgh/t-13290/2000 NNNNNNNNAAAAAANNNNNNNAAAAANNNNNAAAAANNNNAA ZZZZZZZYYYYYYYAAAAAAABBBBBBBCCCCNNNNNNNNNN

我已经很长时间没有使用 awk 了，我不确定数组和键是如何工作的。

更新： 我尝试编写一个 awk 脚本来执行上述操作。检查它们的条件有效，但不知怎的，我在编写 1.txt 中的行与 2.txt 中的行不匹配时仍然遇到问题。

BEGIN{
    i = 0;
    j = 0;
    k = 0;
    maxi = 0;
    maxj = 0;
    maxk = 0;
    FS = "\/";
}

FILENAME == ARGV[1]{
    header1=substr($0,1,1);
    if(header1==">"){
        ++maxi;
        seqcode1[maxi]=substr($0,2,5);
#       printf("%s\n",seqcode1[maxi]);
    }
    else if(header1!=">"){
        ++maxk;
        seqFASTA[maxk]=$0;
#       print seqFASTA[maxk];
    }
}

FILENAME == ARGV[2]{
    header2=substr($0,1,1);
    if(header2=="h"){
        ++maxj;
        wholename[maxj]=$0;
        seqcode2[maxj]=substr($3,4,5);
#       printf("%s\n",seqcode2[maxj]);
    }
}

END{
    for(i=1;i<=maxi=maxk;i++){
      for(j=1;j<=maxj;j++){
        if(seqcode1[i] == seqcode2[j]) {
            printf("%s %s %s\n",seqcode1[i],seqcode2[j],wholename[j]);
        }
        else
          print seqcode1[i];
          print seqFASTA[k];
        }
    }
}

我认为问题可能在于声明 seqFASTA 但我不确定在哪里。

非常感谢！ M。

Answer 1

我假设 1.txt 中的 13920 应该是 13290。

$ awk 'NR==FNR{split($0, a, "/"); sub(/^[^-]+-/, "", a[3]); map[a[3]]=$0; next}
       (k=substr($0, 2)) in map{$0 = ">" map[k]} 1' 2.txt 1.txt
>hbcd/efgh/z-01234/2000
NNNNNNNNAAAAAANNNNNNAAAAANNNNAAAAANNNNAA
>17321
SSSSSSKKKKKKLLLLLIIIIIIMMMMMMNNNNNNAAAA
>hbcd/efgh/t-13290/2000
ZZZZZZZYYYYYYYAAAAAAABBBBBBBCCCCNNNNNNNNNN

以下是一些替代解决方案：

# with GNU awk
awk 'NR==FNR{match($0, /-([0-9]+)/, a); map[a[1]]=$0; next}
     (k=substr($0, 2)) in map{$0 = ">" map[k]} 1' 2.txt 1.txt

# assuming '/' and '-' will always be similar to given sample
awk -F'[/-]' 'NR==FNR{map[$4]=">"$0; next}
              $2 in map{$0 = map[$2]} 1' 2.txt FS='>' 1.txt