Julia JuMP 确保非线性目标函数具有正确的函数签名，以便自微分正常工作？

Question

所以我写了一个最小的例子来展示我正在尝试做的事情。基本上我想解决具有多个变量的优化问题。当我尝试在 JuMP 中执行此操作时，我遇到了函数 obj 无法获取forwardDiff 对象的问题。

我看了这里：这似乎与函数签名有关：限制函数在 Julia 中使用 ForwardDiff 时的签名 。我在 obj 函数中执行了此操作，并且为了保险起见，也在我的子函数中执行了此操作，但我仍然收到错误

 LoadError: MethodError: no method matching Float64(::ForwardDiff.Dual{ForwardDiff.Tag{JuMP.var"#110#112"{typeof(my_fun)},Float64},Float64,2})
Closest candidates are:
  Float64(::Real, ::RoundingMode) where T<:AbstractFloat at rounding.jl:200
  Float64(::T) where T<:Number at boot.jl:715
  Float64(::Int8) at float.jl:60

“这仍然不起作用”。我觉得我的大部分代码都是正确的，只是发生了一些奇怪的类型的事情，我必须清理这些事情，以便自动微分工作......

有什么建议吗？

using JuMP
using Ipopt
using LinearAlgebra

function obj(x::Array{<:Real,1})
    println(x)
    x1 = x[1]
    x2 = x[2]
    eye= Matrix{Float64}(I, 4, 4)
    obj_val = tr(eye-kron(mat_fun(x1),mat_fun(x2)))
   println(obj_val)
   return obj_val
end

function mat_fun(var::T) where {T<:Real}
    eye= Matrix{Float64}(I, 2, 2)
    eye[2,2]=var
    return eye

end

m = Model(Ipopt.Optimizer)

my_fun(x...) = obj(collect(x))

@variable(m, 0<=x[1:2]<=2.0*pi)
register(m, :my_fun, 2, my_fun; autodiff = true)
@NLobjective(m, Min, my_fun(x...))

optimize!(m)

# retrieve the objective value, corresponding x values and the status
println(JuMP.value.(x))
println(JuMP.objective_value(m))
println(JuMP.termination_status(m))

Answer 1

使用替代

function obj(x::Vector{T}) where {T}
    println(x)
    x1 = x[1]
    x2 = x[2]
    eye= Matrix{T}(I, 4, 4)
    obj_val = tr(eye-kron(mat_fun(x1),mat_fun(x2)))
   println(obj_val)
   return obj_val
end

function mat_fun(var::T) where {T}
    eye= Matrix{T}(I, 2, 2)
    eye[2,2]=var
    return eye
end

本质上，在任何看到 Float64 的地方，将其替换为传入参数中的类型。

Answer 2

我发现了问题：
在我的 mat_fun 中，返回的类型必须是“Real”才能传播。之前是 Float64，这与我猜想所有类型都必须是具有自动微分功能的 Real 的事实不一致。尽管 Float64 显然是 Real，但看起来继承并没有得到保留，即您必须确保返回和输入的所有内容都是 Real 类型。

using JuMP
using Ipopt
using LinearAlgebra

function obj(x::AbstractVector{T}) where {T<:Real}
    println(x)
    x1 = x[1]
    x2 = x[2]
    eye= Matrix{Float64}(I, 4, 4)
    obj_val = tr(eye-kron(mat_fun(x1),mat_fun(x2)))
   #println(obj_val)
   return obj_val
end

function mat_fun(var::T) where {T<:Real}
    eye= zeros(Real,(2,2))
    eye[2,2]=var
    return eye

end

m = Model(Ipopt.Optimizer)

my_fun(x...) = obj(collect(x))

@variable(m, 0<=x[1:2]<=2.0*pi)
register(m, :my_fun, 2, my_fun; autodiff = true)
@NLobjective(m, Min, my_fun(x...))

optimize!(m)

# retrieve the objective value, corresponding x values and the status
println(JuMP.value.(x))
println(JuMP.objective_value(m))
println(JuMP.termination_status(m))