如何检查 Perl 中传递的命令行参数的数量？

Question

我有一个按以下方式运行的脚本：

perl testing.pl -grid 24 -range 97   ## Here, arguments passed are processed via getopt::Long module.

现在，我想检查传递给脚本的命令行参数的数量。预期是 2。但我得到 0。

我在脚本 (testing.pl) 中使用了下面的代码来提取参数数量：

my $totalCmdLineArg = $#ARGV + 1;
print "$totalCmdLineArg is total command line arguments\n";
if ($totalCmdLineArg <= 0 ) {
    $defaultmode=1;
} else {
    $defaultmode=0;
}

在这里，我得到“0 是命令行参数总数”作为输出。我希望“2 是总命令行参数”作为输出。我怎样才能得到预期的答案？

注意：有 100 多个参数，其中任何一个都可以传递。

Answer 1

调用 GetOptions 后，您无法对选项进行计数。 GetOptions 从 @ARGV 中删除它识别的选项。引用其文档：

命令行选项取自数组@ARGV。完成 GetOptions 后，@ARGV 将包含命令行的其余部分（即非选项）。

此外，GetOptions 不会计算它解析的选项数量。如果您需要说服力，请查看来源。

因此，如果您想计算传递给程序的选项数量，您必须在调用 GetOptions 之前手动执行此操作。

如果命令行上的所有参数都采用 --option xxx 形式，那么您可以简单地执行以下操作（在调用 GetOptions 之前）

my $totalCmdLineArg = grep { /^--/ } @ARGV

： ，这忽略了 -- 本身在 @ARGV 中标记选项列表结尾的事实。如果您的命令行类似于 perl prog.pl --opt1 v1 --opt2 v2 -- some extra --arguments 那么 -- 和 --arguments 实际上不是选项（对于 GetOptions）。要处理这种情况，您必须编写类似以下内容的内容：

my $totalCmdLineArg = 0;
for (@ARGV) {
    last if $_ eq '--';
    $totalCmdLineArg++ if /^--/;
}

但是，这并不能说明单个 - 可用于启动选项，并且可用于组合多个选项（$Getopt::Long::bundling 为非零）。您必须调整上面的代码来处理这种情况。

---

仅在最后手段（不要在生产中使用，可能随时崩溃）：
如果您正在使用 bundling 和 Getopt::Long 的其他复杂功能，您可以稍微修改一下来计算有多少个 Getopt::Long 选项实际上发现。在内部，GetOptions 调用 FindOption 来实际查找选项。您可以重新定义它来计算找到的选项数量：

my $opt_count = 0;
{
  no warnings qw(redefine prototype);
  my $original_FindOption = \&Getopt::Long::FindOption;
  *Getopt::Long::FindOption = sub {
    my @ret = &$original_FindOption;
    if ($ret[0] && defined $ret[1]) {
      $opt_count++;
    }
    return @ret;
  };
}

请注意，这是一种非常脆弱的方法：FindOption 不是 Getopt::Long 公开的 API 的一部分，并且因此，版本之间可能会发生变化，这可能会破坏此代码。

Answer 2

有四个个参数。二是选项的数量。

GetOptions 不提供找到的选项数量，但有一个简单而干净的方法可以做到这一点。首先，使用 GetOptions( HASHREF, ... ) 调用约定。那么，这只是一个计算哈希中元素数量的问题。

GetOptions( \my %opts,
   "grid=i",
   "range=i",
   ...
)
   or usage();

my $num_options = keys( %opts );

该解决方案适用于所有类型的选项（带值、不带值、捆绑等）。它甚至避免计算重复项。

与之前的答案不同，此解决方案不需要在调用者中重新实现GetOptions（之前的答案做得很糟糕，它声称OP的示例perltesting.pl -grid 24 -range 977 包含零个选项）或猴子修补模块。