访问未定义的 stage_in Metal 着色器参数

Question

我正在 Metal 中构建一个简约的 3D 引擎，我希望我的顶点和片段着色器代码尽可能可重用，以便我的顶点着色器可以无论其输入网格顶点数据布局如何，都可以在不更改的情况下使用。

我遇到的一个问题是，我不能保证所有网格体都具有相同的属性，例如，一个网格体可能只包含其位置和法线数据，而另一个网格体可能还附加了 UV 坐标。

现在我的第一个问题是，如果我像这样定义我的顶点着色器输入结构：

struct VertexIn {
    float3 position [[ attribute(0) ]];
    float3 normal [[ attribute(1) ]];
    float2 textureCoordinate [[ attribute(2) ]];
};

我想知道如果我的金属顶点描述符中没有指定的属性 2，这样做的后果是什么？我的测试似乎表明没有崩溃（至少只是在输入纹理中定义这样的参数），但我想知道这是否只是未定义的行为或者这实际上是否安全？

我遇到的另一个问题是，我可能想将 uv 纹理信息传递给片段着色器（即：从我的顶点着色器返回它），但如果它丢失会发生什么？感觉除非专门以这种方式设计，否则访问textureCooperative以将其值设置为我从顶点着色器返回的某些VertexOut结构的属性将是未定义的行为。

另外，我注意到苹果的 RealityKit 框架一定找到了解决这个问题的方法：它使用户能够指向“着色器修改器”函数，这些函数传递顶点和片段着色器的数据，以便他们可以对其采取行动，令我惊讶的是用户函数传递的结构定义了很多属性，我不确定这些属性是否总是为所有网格定义（例如，第二个 UV 纹理）。这看起来与我试图解决的问题非常相似。

我是否缺少一些明显的方法来解决这个问题？

Answer 1

我认为处理这个问题的预期方法是函数常量。这是我如何在顶点着色器中处理此问题的示例。

constant bool HasColor0 [[ function_constant(FunctionConstantHasColor0) ]];
constant bool HasNormal [[ function_constant(FunctionConstantHasNormal) ]];
constant bool HasTangent [[ function_constant(FunctionConstantHasTangent) ]];
constant bool HasTexCoord0 [[ function_constant(FunctionConstantHasTexCoord0) ]];
constant bool AlphaMask [[ function_constant(FunctionConstantAlphaMask) ]];

// ... 

struct VertexIn
{
    float3 position [[ attribute(AttributeBindingPosition) ]];
    float3 normal [[ attribute(AttributeBindingNormal), function_constant(HasNormal) ]];
    float4 tangent [[ attribute(AttributeBindingTangent), function_constant(HasTangent) ]];
    float4 color [[ attribute(AttributeBindingColor0), function_constant(HasColor0) ]];
    float2 texCoord [[ attribute(AttributeBindingTexcoord0), function_constant(HasTexCoord0) ]];
};

struct VertexOut
{
    float4 positionCS [[ position ]];
    float4 tangentVS = float4();
    float3 positionVS = float3();
    float3 normalVS = float3();
    float2 texCoord = float2();
    half4 color = half4();
};

static VertexOut ForwardVertexImpl(Vertex in, constant CameraUniform& camera, constant MeshUniform& meshUniform)
{
    VertexOut out;

    float4x4 viewModel = camera.view * meshUniform.model;
    float4 positionVS = viewModel * float4(in.position.xyz, 1.0);
    out.positionCS = camera.projection * positionVS;
    out.positionVS = positionVS.xyz;

    float4x4 normalMatrix;
    if(HasNormal || HasTangent)
    {
        normalMatrix = transpose(meshUniform.inverseModel * camera.inverseView);
    }

    if(HasNormal)
    {
        out.normalVS = (normalMatrix * float4(in.normal, 0.0)).xyz;
    }

    if(HasTexCoord0)
    {
        out.texCoord = in.texCoord;
    }

    if(HasColor0)
    {
        out.color = half4(in.color);
    }
    else
    {
        out.color = half4(1.0);
    }

    if(HasTangent)
    {
        // Normal matrix or viewmodel matrix?
        out.tangentVS.xyz = (normalMatrix * float4(in.tangent.xyz, 0.0)).xyz;
        out.tangentVS.w = in.tangent.w;
    }

    return out;
}

vertex VertexOut ForwardVertex(
    VertexIn in [[ stage_in ]],
    constant CameraUniform& camera [[ buffer(BufferBindingCamera) ]],
    constant MeshUniform& meshUniform [[ buffer(BufferBindingMesh) ]])
{
    Vertex v
    {
        .color = in.color,
        .tangent = in.tangent,
        .position = in.position,
        .normal = in.normal,
        .texCoord = in.texCoord,
    };

    return ForwardVertexImpl(v, camera, meshUniform);
}

在主机应用程序中，我根据几何实际具有的语义填写了 MTLFunctionConstantValues 对象：

func addVertexDescriptorFunctionConstants(toConstantValues values: MTLFunctionConstantValues) {
    var unusedSemantics = Set<AttributeSemantic>(AttributeSemantic.allCases)

    for attribute in attributes.compactMap({ $0 }) {
        unusedSemantics.remove(attribute.semantic)

        if let constant = attribute.semantic.functionConstant {
            values.setConstantValue(true, index: constant)
        }
    }

    for unusedSemantic in unusedSemantics {
        if let constant = unusedSemantic.functionConstant {
            values.setConstantValue(false, index: constant)
        }
    }
}

这样做的好处是编译器应该将这些函数常量 if 转换为代码没有分支，所以在运行时它应该不是真正的问题，并且这可以让您离线编译着色器，而不必使用在线编译和定义。