序言。如何返回范围内的整数列表

Question

我想返回给定输入的整数列表： rList :- (X,Y,[]) (1,4, N) 返回 N= [1,2,3,4]。 这也需要适用于负整数，反之亦然 输入 (4,-2, N) 返回 N= [4,3,2,1,0,-1,-2]。

到目前为止，我已经编写了开头的程序，但我被困住了。有人可以向我解释我应该如何继续吗？

rList(_ , _ ,[ ]).
rList(X, Y, [X|T])  :-
    must_be(integer, X),
    must_be(integer, Y),
    X =< Y,
    N is X + 1,
    rList(N,Y,T).

返回：rList(1,4,N) N= [], [1], [1,2], [1,2,3], [1,2,3,4], false。此外，所有这些第一步不应因此而被退回。我只需要最后一个列表 ([1,2,3,4]) 作为输出。

Answer 1

为了性能，增量或减量决策应该一次，所以这里是：

range_list2(IntStart, IntEnd, Lst) :-
    integer(IntStart),
    integer(IntEnd),
    IntInc is sign(IntEnd - IntStart),
    range_list2_(IntStart, IntEnd, IntInc, Lst).
    
range_list2_(Int, Int, _IntInc, [Int]) :- !.
range_list2_(IntUpto, IntEnd, IntInc, [IntUpto|Lst]) :-
    IntUpto1 is IntUpto + IntInc,
    range_list2_(IntUpto1, IntEnd, IntInc, Lst).

swi-prolog 中的结果：

?- time(range_list2(-5, 5, L)).
% 23 inferences, 0.000 CPU in 0.000 seconds (89% CPU, 438237 Lips)
L = [-5,-4,-3,-2,-1,0,1,2,3,4,5].

?- time(range_list2(5, -5, L)).
% 23 inferences, 0.000 CPU in 0.000 seconds (89% CPU, 430623 Lips)
L = [5,4,3,2,1,0,-1,-2,-3,-4,-5].

Answer 2

一个可能的解决方案是：

range(Start, Stop, List) :-
    must_be(integer, Start),
    must_be(integer, Stop),
    findall(X, elem(Start,Stop,X), List).

elem(Start, Stop, Element) :-
    Step is sign(Stop-Start),
    N is abs(Stop-Start),
    between(0, N, I),
    Element is Start + I*Step.

示例：

?- range(1, 4, L).
L = [1, 2, 3, 4].

?- range(4, 1, L).
L = [4, 3, 2, 1].

?- range(-3, 3, L).
L = [-3, -2, -1, 0, 1, 2, 3].

?- range(5, 5, L).
L = [5].

?- range(5, 5, []).
false.

?- range(5, 6, [5, 6]).
true.

?- range(-5, -1, L).
L = [-5, -4, -3, -2, -1].

?- range(-1, -5, L).
L = [-1, -2, -3, -4, -5].

Answer 3

解决方案 1（常见解决方案）：

?- findall(X, between(-2,4,X) , L).
L = [-2,-1,0,1,2,3,4].

解决方案 2（实现内置 Between）：

my_between(L, U, X) :-
  L =< U, !,
  (   X = L 
  ;   L1 is L + 1,
      my_between(L1, U, X) ).

?- my_between(-2,4,X).
X = -2 ;
X = -1 ;
X = 0 ;
X = 1 ;
X = 2 ;
X = 3 ;
X = 4 ;
false.;

解决方案 3（遵循您的解决方案）：

rList(X, Y ,[]) :- X > Y, !.
rList(X, Y, [X|T]) :-
  N is X + 1,
  rList(N,Y,T).

?- rList(-2, 4, L).
L = [-2,-1,0,1,2,3,4].

?- rList(4, 4, L).
L = [4].

?- rList(5, 4, L).
L = [].

--- 编辑 ---

谢谢@slago，我没有注意到这两个-way 要求，但它可以很容易实现：

my_between2(U, L, X) :-
  L =< U, !,
  (   X = U 
  ;   U1 is U - 1,
      my_between2(U1, L, X) ).


bi_between(L, U, X) :- L =< U, !, my_between(L, U, X).
bi_between(U, L, X) :- my_between2(U, L, X).

?- findall(X, bi_between(-2,4,X) , L).
L = [-2,-1,0,1,2,3,4].

?- findall(X, bi_between(4,-2,X) , L).
L = [4,3,2,1,0,-1,-2].

另外，对于 rList：

bi_rList(X, Y ,L) :- X =< Y, !, rList(X,Y,L).
bi_rList(X, Y, L) :- rList(Y,X,L1), reverse(L1,L).

?- bi_rList(-2, 4, L).
L = [-2,-1,0,1,2,3,4].

?- bi_rList(4, -2, L).
L = [4,3,2,1,0,-1,-2].

Answer 4

只需一个简单的操作

range(B,B,[B]).
range(A,B,[A|Ns]) :- A < B , A1 is A+1, range(A1,B,Ns) .
range(A,B,[A|Ns]) :- A > B , A1 is A-1, range(A1,B,Ns) .

就可以解决问题。如果你需要保护它，一个简单的装饰器就可以了：

range( A , B , Ns ) :- integer(A), integer(B), range_(A,B,Ns) .

range_( B , B , [B]    ) .
range_( A , B , [A|Ns] ) :- A < B , A1 is A+1, range_(A1,B,Ns) .
range_( A , B , [A|Ns] ) :- A > B , A1 is A-1, range_(A1,B,Ns) .