如何在每行前面加上 awk 找到的模式实例

Question

我有一个包含很多行的文件。有些行显示日期和时间，例如 2022-03-16-08:00

我希望发现的模式后面的所有行都预先考虑了该模式

此外，因为有许多行具有不同的时间，所以我希望每个行都改变这一点模式的实例，并在该实例的以下行前面添加相应的日期和时间。

例如，我有以下文件 (example.txt)：

Date1: 2022-03-16-08:00
Something happened
Something else happened
Date2: 2022-03-16-08:10
Something happened
Something else happened
Something else happened

我想要的结果是：

Date1: 2022-03-16-08:00
2022-03-16-08:00 Something happened
2022-03-16-08:00 Something else happened
Date2: 2022-03-16-08:10
2022-03-16-08:10 Something happened
2022-03-16-08:10 Something else happened
2022-03-16-08:10 Something else happened

我尝试使用 sed 将找到的模式添加到彼此行的前面，但 sed 变量似乎不起作用：

sed -e '/2022-/s/\(.*\)/\1/' -e 's/^/$1/' example.txt

结果：

$1Date1: 2022-03-16-08:00
$1Something happened
$1Something else happened
$1Date2: 2022-03-16-08:10
$1Something happened
$1Something else happened
$1Something else happened

我认为用 awk 可能是可行的，采取awk -F 的模式： '/2022/{var=$2}' 然后将其添加到下一行，但我不知道如何将其更改为 Date 的新实例

任何帮助都是值得赞赏和非常欢迎的。

Answer 1

我将按照以下方式让 GNU AWK 完成此任务，让 file.txt 内容

Date1: 2022-03-16-08:00
Something happened
Something else happened
Date2: 2022-03-16-08:10
Something happened
Something else happened
Something else happened

然后

awk 'BEGIN{FPAT="[0-9]{4}-[0-9]{2}-[0-9]{2}-[0-9]{2}:[0-9]{2}"}NF{when=$1;print}!NF{print when,$0}' file.txt

输出

Date1: 2022-03-16-08:00
2022-03-16-08:00 Something happened
2022-03-16-08:00 Something else happened
Date2: 2022-03-16-08:10
2022-03-16-08:10 Something happened
2022-03-16-08:10 Something else happened
2022-03-16-08:10 Something else happened

说明：在 BEGIN 内部我通知 GNU AWK 使用 FPAT （字段 PATtern），它应该将字段视为以下字符串：4 位数字，后跟 - 后跟 2 位数字，后跟 -< /code> 后接 2数字后跟 - 后跟 2 位数字，后跟 : 后跟 2 位数字，即时间戳符合您正在使用的格式。对于每一行，如果它确实包含此类文件（即 NF 的字段数量非零），请为第一个此类字段的内容设置 when 变量值（>$1) 并按原样 print 当前行，如果没有这样的字段（!NF 是 NF 的否定) 然后打印 when 变量值，后跟整个当前行（$0）。

警告：我的代码假设如果您在单行中有多个时间戳，您希望使用第一个时间戳，并且第一行中始终有时间戳

（在 gawk 4.2.1 中测试）

Answer 2

使用 sed：

sed -e '/: 2[0-9]\{3\}-/{p;s/.*: //;h;d;}' -e 'G;s/\(.*\)\n\(.*\)/\2 \1/' example.txt

Answer 3

此解决方案应该适用于任何版本的 awk：

awk -F ': ' 'NF == 2 && $2 ~ /^20[0-9]{2}/ {
   dt = $2; print; next} {print dt, $0}' file.log

Date1: 2022-03-16-08:00
2022-03-16-08:00 Something happened
2022-03-16-08:00 Something else happened
Date2: 2022-03-16-08:10
2022-03-16-08:10 Something happened
2022-03-16-08:10 Something else happened
2022-03-16-08:10 Something else happened

Answer 4

对于显示的示例，请尝试执行以下 awk 代码。在 GNU awk 中编写和测试，应该可以在任何 awk 中工作。

awk '
match($0,/[0-9]{4}(-[0-9]{2}){3}:[0-9]{2}/){
  value=substr($0,RSTART,RLENGTH)
  print
  next
}
{
  print value,$0
}
'  Input_file