带curl的Delphi Indy http.get返回：未经授权

Question

根据供应商数据，我应该有：

• Http 类型 GET
• 响应类型：application/json
• 参数：授权：bearer + Token
• Curl：curl -X GET --header '接受：application/json' --header '授权：bearer + Token , 'http://localhost:8080/api/v1/doors'
• 请求 URL: 'http://localhost:8080/api/v1/doors'

我已将其翻译为Delphi(Indy TidHttp)：

procedure TForm42.Button2Click(Sender: TObject);
var
  resp: TMemoryStream;
begin
  resp := TMemoryStream.Create;
  try
    IdHTTP1.Request.Clear;
    IdHTTP1.Request.Accept := 'application/json';
    IdHTTP1.Request.BasicAuthentication := True;
    IdHTTP1.Request.CustomHeaders.FoldLines := False;
    IdHTTP1.Request.CustomHeaders.Values['Authorization'] := 'Bearer ' + TokenStr;
    IdHTTP1.Get('http://10.10.1.62:8080/api/v1/doors', resp);
    resp.Position := 0;
    memCall.Lines.LoadFromStream(resp);
  finally
    resp.Free;
  end;
end;

我在这里读了很多相关内容，所以最后我还添加了“折叠线”(向 TIdHttp 请求添加自定义标头，标头值有逗号) 我还尝试了“X-Authorization”作为参数，这是我从 R. Lebeau 那里读到的，但我得到的唯一反应是一个错误对话框，上面写着“401 未经授权”。

我对令牌字符串（->'bearer' + TokenStr）很确定，因为我在将字符串放入供应商试用时得到了答案。

有人知道我做错了什么吗？

Answer 1

使用自定义身份验证时，Request.BasicAuthentication 应为 False 而不是 True。

并且您不需要设置 CustomHeaders.FoldLines 因为 TIdHTTP 已经默认禁用折叠（当时默认情况下并未禁用 另一个问题已发布）。

否则，代码的其余部分看起来不错。

不过，我建议在调用 LoadFromStream() 时指定 TEncoding.UTF8)，例如：

procedure TForm42.Button2Click(Sender: TObject);
var
  resp: TMemoryStream;
begin
  resp := TMemoryStream.Create;
  try
    IdHTTP1.Request.Clear;
    IdHTTP1.Request.Accept := 'application/json';
    IdHTTP1.Request.BasicAuthentication := False;
    IdHTTP1.Request.CustomHeaders.Values['Authorization'] := 'Bearer ' + TokenStr;
    IdHTTP1.Get('http://10.10.1.62:8080/api/v1/doors', resp);
    resp.Position := 0;
    memCall.Lines.LoadFromStream(resp, TEncoding.UTF8);
  finally
    resp.Free;
  end;
end;

或者，使用 TIdHTTP.Get() 的重载code> 返回一个字符串：

procedure TForm42.Button2Click(Sender: TObject);
begin
  IdHTTP1.Request.Clear;
  IdHTTP1.Request.Accept := 'application/json';
  IdHTTP1.Request.BasicAuthentication := False;
  IdHTTP1.Request.CustomHeaders.Values['Authorization'] := 'Bearer ' + TokenStr;
  memCall.Text := IdHTTP1.Get('http://10.10.1.62:8080/api/v1/doors');
end;