将预编译库集成到 C++使用 CMakeExternalProject 的代码库

Question

我想将CasADi集成到CMake 的 C++ 代码库作为 ExternalProject。 为此，我想使用预编译库，因为从源代码构建是 不推荐。到目前为止，我只编写了以下内容：

ExternalProject_Add(
  casadi-3.5.5
  URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
  CONFIGURE_COMMAND ""
  BUILD_COMMAND ""
  INSTALL_COMMAND ""
  PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

并且我注意到所有二进制文件都已正确下载到指定的文件夹中。但是，我不知道如何将我的目标链接到CasADi，也不知道如何找到该包。

Answer 1

ExternalProject_Add 有一个天然的问题：

ExternalProject_Add 仅在构建时执行命令。

因此，在项目的配置阶段不会进行下载，这使得使用 find_package 变得困难，因为在项目配置阶段无法找到文件。首先配置运行。

获取此 CMakeLists.txt：

cmake_minimum_required(VERSION 3.21)
project(untitled)

set(CMAKE_CXX_STANDARD 17)

add_executable(untitled main.cpp)

include(ExternalProject)
ExternalProject_Add(
        casadi-3.5.5
        URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
        PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

find_package(casadi HINTS ${CMAKE_BINARY_DIR}/external/casadi/src/casadi-3.5.5/casadi)

target_link_libraries(untitled casadi)

为了使用它，您必须执行以下操作：

1. 配置您的项目

mkdir build
cd build
cmake ..

2. 构建（下载） casadi-3.5.5

cmake --build . --target casadi-3.5.5

3. 重新配置您的项目，因为现在 find_package 将找到所需的文件

cmake ..

4. 构建你的目标

cmake --build .

---

如果你想要一步构建，有一些方法可以解决这个问题

• 使用 FetchContent
• 使用所有 ExternalProject_Add 命令在子文件夹中创建子 cmake 项目，并通过 在您自己的 CMakeLists.txt 中手动执行适当的构建（下载）步骤execute_process 调用：https://stackoverflow.com/a/37554269/8088550

---

这是第二个选项的示例，由于 FetchContent 可能会更好不具备ExternalProject的全部功能。

• main.cpp

#include <casadi/casadi.hpp>

int main()
{
    casadi_printf("This works!");
    return 0;
}

• CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(untitled)

set(CMAKE_CXX_STANDARD 17)

# some default target
add_executable(untitled main.cpp)

# Configure and build external project
file(MAKE_DIRECTORY ${CMAKE_BINARY_DIR}/external)
execute_process(
        COMMAND ${CMAKE_COMMAND} ${CMAKE_SOURCE_DIR}/external
        WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/external
)
execute_process(
        COMMAND ${CMAKE_COMMAND} --build ${CMAKE_BINARY_DIR}/external
)

# find and link externals
find_package(casadi REQUIRED HINTS ${CMAKE_BINARY_DIR}/external/external/casadi/src/casadi-3.5.5/casadi)
target_link_libraries(untitled casadi)

• external/CMakeLists.txt

cmake_minimum_required(VERSION 3.20)
project(external)

include(ExternalProject)
ExternalProject_Add(
        casadi-3.5.5
        URL https://github.com/casadi/casadi/releases/download/3.5.5/casadi-linux-py39-v3.5.5-64bit.tar.gz
        CONFIGURE_COMMAND ""
        BUILD_COMMAND ""
        INSTALL_COMMAND ""
        PREFIX ${CMAKE_BINARY_DIR}/external/casadi)

重点是在external/CMakeLists.txt<下有另一个cmake项目/code>，它通过主 cmake 项目的 execute_process 调用进行配置和构建。请注意，您现在可以在配置阶段使用 find_package(casadi REQUIRED ...)，因为下载将在之前进行。