未找到 Mojolicious 控制器中的模板

Question

我正在尝试提供控制器类的 __DATA__ 部分中包含的模板，但它似乎不起作用。

在我的主 app.pl 文件中

#!/usr/bin/env perl
use Mojolicious::Lite -signatures;
use FindBin qw($Bin);
use lib "$Bin/lib";


push @{app->renderer->classes},   'Zairyo::Controller::Data';
push @{app->preload_namespaces},  'Zairyo::Controller::Data';

get '/:uid'  => [uid => qr/[a-z0-9]{32,32}/i ] => { controller => 'Data', action => 'serve_iframe' };

app->start;

，在 Zairyo::Controller::Data: 中，

package Zairyo::Controller::Data;

use Mojo::Base 'Mojolicious::Controller', -signatures;

sub serve_iframe ($c) {
    $c->render(template => 'foo');
}

__DATA___

@@ foo.html.ep
what is this

我希望它能够按照 文档，而是在浏览器上抛出错误 无法呈现响应... 模板在日志中找不到“foo.html.ep”。

我已经通过这样做解决了这个问题

$c->render(inline => data_section(__PACKAGE__, 'foo.html.ep') );

，但这似乎有点黑客。

我在这里做错了什么？

Answer 1

首先，Data.pm 中存在一些问题：

• __DATA 后有三个下划线，而本应有两个下划线和一个换行符
• 模块不返回真实值

这是我最终得到的结果：

package Zairyo::Controller::Data;

use Mojo::Base 'Mojolicious::Controller', -signatures;

sub serve_iframe ($c) {
    $c->render(template => 'foo' );
}

1;

__DATA__

@@ foo.html.ep
what is this

在主脚本中，我在调用 start 之前加载该类。请注意，文档说：

请注意，要检测模板，需要在调用预热之前加载并添加这些类

，并且 warmup 会立即由 start 调用，并且它是 关心 preload_namespaces 的预热。您需要更快地到达那里，因此 preload_namespaces 对这个特定问题没有任何作用。如果您尚未加载该模块，则不会检测到其 __DATA__ 模板。

#!/usr/bin/env perl
use Mojolicious::Lite -signatures;
use FindBin qw($Bin);
use lib "$Bin/lib";

push @{app->renderer->classes}, map { Mojo::Loader::load_class($_); $_ } 'Zairyo::Controller::Data';

get '/:uid'  => [uid => qr/[a-z0-9]{32,32}/i ] => {
    namespace  => 'Zairyo::Controller',
    controller => 'Data',
    action     => 'serve_iframe'
    };

app->start;

我并不是建议这个特定的代码，但现在我知道为什么你没有得到你想要的东西。