如何开始&使用代码在AnimationTree中旅行？

Question

我正在尝试通过在 AnimationTree 中的节点之间移动来为可扩展的人员设置动画，如下所示：

...
tool

export(String,"small", "mid", "full") var staff_mode = "small" setget set_staff_mode;

func set_staff_mode(new_val):
    
    var ani_state;
    if(self.has_node("/path/to/AnimationTree")):
        ani_state=self.get_node("/path/to/AnimationTree")["parameters/playback"];
        ani_state.start(staff_mode);
        print(ani_state.is_playing());
        ani_state.travel(new_val);
        ani_state.stop();
        
    staff_mode=new_val;

我尚未对 small 应用自动播放，因为我不想要一个工作人员上的循环动画
（它只扩展或压缩，没有空闲动画）

但由于某种原因它给出了错误：

如果状态机未运行，则无法进入“满”状态。也许你 需要为您所在州的节点之一启用加载时自动播放 机器还是先调用.start()？

编辑： 我忘了提及，但我的员工没有任何空闲动画，因此我需要在过渡完成后停止动画。

小型、中型和小型完整
（所有这些都是法杖的静态模式，具体取决于游戏法杖应该延伸多少）
都是 0.1 秒的单帧动画，我应用了 0.2 秒的 Xfade 时间来显示过渡

，我只需要从现有的动画状态过渡到另一个状态，然后停止

Answer 1

---

新答案

显然旧答案的解决方案不适用于非常短的动画。对于我的口味来说，这些变通办法似乎开销太大了。因此，作为替代方案，让我们摆脱 AnimationTree 并直接使用 AnimationPlayer。为此，我们将：

1. 增加动画持续时间，使其足够长以适应“交叉淡入淡出”时间（例如 0.2 秒）。
2. 将“交叉淡入淡出”时间放入“交叉动画混合时间”中。对于每个动画，在“动画”面板上选择它，然后从动画菜单中选择“编辑过渡...”，这将打开“跨动画混合时间”，您可以在其中指定其他动画的过渡时间（例如 0 到自身， 0.1 到“相邻”动画，依此类推）。

现在我们可以简单地要求 AnimationPlayer 进行播放，如下所示：

tool
extends Node2D

enum Modes {full, mid, small}
export(Modes) var staff_mode setget set_staff_mode

func set_staff_mode(new_val:int) -> void:
    if staff_mode == new_val:
        return

    if not is_inside_tree():
        return

    var animation_player := get_node("AnimationPlayer") as AnimationPlayer
    if not is_instance_valid(animation_player):
        return

    var target_animation:String = Modes.keys()[new_val]
    animation_player.play(target_animation)
    yield(animation_player, "animation_finished")
    staff_mode = new_val
    property_list_changed_notify()

我选择使用枚举，因为这也允许我在动画之间“旅行”。我们的想法是，我们将创建一个 for 循环，在其中按顺序调用动画。像这样：

tool
extends Node2D

enum Modes {full, mid, small}
export(Modes) var staff_mode:int setget set_staff_mode

func set_staff_mode(new_val:int) -> void:
    if staff_mode == new_val:
        return

    if not is_inside_tree():
        return

    var animation_player := get_node("AnimationPlayer") as AnimationPlayer
    if not is_instance_valid(animation_player):
        return

    var old_val := staff_mode
    staff_mode = new_val
    var travel_direction = sign(new_val - old_val)
    for mode in range(old_val, new_val + travel_direction, travel_direction):
        var target_animation:String = Modes.keys()[mode]
        animation_player.play(target_animation)
        yield(animation_player, "animation_finished")

我还决定尽早设置 staff_mode，这样我就可以避免 property_list_changed_notify。

并发调用可能会导致动画提前停止，因为调用 play 会停止当前正在播放的动画以播放新动画。但是，我认为等待当前动画结束是不正确的。而且对于如此短的动画，这应该不是问题。

---

使用 Tween 的版本

使用 Tween 将为您提供更好的控制，但它也需要更多工作，因为我们要对动画进行编码在代码中...我将使用 interpolate_property 来完成此操作。值得庆幸的是，这是一个相当简单的动画，因此可以在不使代码太长的情况下进行管理。

当然，你需要添加一个Tween节点。我们不会使用 AnimationPlayer 或 AnimationTree。 Tween 将处理插值（您甚至可以通过添加 interpolate_property 的可选参数来指定如何进行插值，我在这里没有传递该参数）。

这是代码：

tool
extends Node2D

enum Modes {full, mid, small}
export(Modes) var staff_mode:int setget set_staff_mode

func set_staff_mode(new_val:int) -> void:
    if staff_mode == new_val:
        return

    if not is_inside_tree():
        return

    var tween := get_node("Tween") as Tween
    if not is_instance_valid(tween):
        return

    var old_val := staff_mode
    staff_mode = new_val
    var travel_direction = sign(new_val - old_val)
    for mode in range(old_val, new_val + travel_direction, travel_direction):
        match mode:
            Modes.full:
                tween.interpolate_property($"1", "position", $"1".position, Vector2.ZERO, 0.2)
                tween.interpolate_property($"1/2", "position", $"1/2".position, Vector2(0, -35), 0.2)
                tween.interpolate_property($"1/2/3", "position", $"1/2/3".position, Vector2(0, -34), 0.2)
            Modes.mid:
                tween.interpolate_property($"1", "position", $"1".position, Vector2.ZERO, 0.2)
                tween.interpolate_property($"1/2", "position", $"1/2".position, Vector2(0, -35), 0.2)
                tween.interpolate_property($"1/2/3", "position", $"1/2/3".position, Vector2.ZERO, 0.2)
            Modes.small:
                tween.interpolate_property($"1", "position", $"1".position, Vector2.ZERO, 0.2)
                tween.interpolate_property($"1/2", "position", $"1/2".position, Vector2.ZERO, 0.2)
                tween.interpolate_property($"1/2/3", "position", $"1/2/3".position, Vector2.ZERO, 0.2)

        tween.start()
        yield(tween, "tween_all_completed")

您在这里可以看到，我已经对源代码中 AnimationPlayer 的轨道中的值进行了编码。使用 Tween，我可以告诉它从轨道的任何值到每个状态的目标位置进行插值。

我不知道与 AnimationPlayer 相比，它的性能是更好还是更差。

---

旧答案

好吧，这个问题有两个方面：

• 旅行 应该播放动画，所以它不是瞬时的。因此，如果您调用 stop 它将无法运行，并且您会收到错误消息。

  


• 啊，但是你也不能调用 start 并连续旅行。您需要等待动画开始。

---

我首先不会从一种状态转到相同的状态：

func set_staff_mode(new_val:String) -> void:
    if staff_mode == new_val:
        return

---

我们需要获取 AnimationTree，因此我们需要进入场景树。这里我使用 yield 所以方法返回，Godot 在收到 "tree_entered" 信号后恢复执行：

    if not is_inside_tree():
        yield(self, "tree_entered")

yield 的缺点是如果在收到信号之前 Node 空闲，则可能会导致错误。因此，如果您不想使用 yield，我们可以这样做：

    if not is_inside_tree():
        # warning-ignore:return_value_discarded
        connect("tree_entered", self, "set_staff_mode", [new_val], CONNECT_ONESHOT)
        return

这里 CONNECT_ONESHOT 确保该信号自动断开。此外，Godot 确保在释放 Node 时断开所有信号，因此这不会出现与 yield 相同的问题。但是，与 yield 不同的是，它不会在方法中间启动，而是会再次调用该方法。

---

好吧，我们得到了AnimationTree：

var animation_tree := get_node("/path/to/AnimationTree")
if not is_instance_valid(animation_tree):
    return

并得到了AnimationNodeStateMachinePlayback：

var ani_state:AnimationNodeStateMachinePlayback = animation_tree.get("parameters/playback")

---

现在，如果它没有播放，我们需要让它播放：

    if not ani_state.is_playing():
        ani_state.start(new_val)

---

现在的问题是：我们需要等待动画开始。

为了代替更好的解决方案，我们将汇集它：

        while not ani_state.is_playing():
            yield(get_tree(), "idle_frame")

之前我建议获取 AnimationPlayer，这样我们就可以等待 "animation_started"，但是那不起作用。

---

最后，现在我们知道它正在播放，我们可以使用travel，并更新状态：

    ani_state.travel(new_val)
    staff_mode = new_val

不要调用stop .

---

您可能还想致电property_list_changed_notify() 在最后，所以 Godot 读取了 staff_mode 的新值，它可能没有注册，因为我们没有立即更改它（相反，我们之前产生了改变它）。 我想您也可以在yield之前更早地更改该值。

---

顺便说一句，如果您希望mid动画在< code>travel，将 AnimationTree 中从 mid 发出的连接从“Immidiate”更改为“AtEnd”。

---

关于等待行程结束和停止的附录

我们可以以与等待 AnimationNodeStateMachinePlayback 开始播放类似的方式旋转等待。这次我们需要池化两件事：

• 动画的当前状态是什么。
• 该动画的播放位置是什么？

只要动画未处于最终状态并且尚未到达动画的结尾，我们就会让一帧通过并再次检查。像这样：

    while (
        ani_state.get_current_node() != new_val
        or ani_state.get_current_play_position() < ani_state.get_current_length()
    ):
        yield(get_tree(), "idle_frame")

然后你可以调用stop。

---

此外，我将添加对 is_playing 的检查。原因是此代码正在等待 AnimationTree 完成我们告诉它的状态...但是如果您在完成之前再次调用 Travel，它将前往新的目的地，因此可能永远不会到达我们期望的状态，这会导致自旋永远等待。

由于它可能没有达到我们预期的状态，我决定查询最终状态，而不是将 staff_mode 设置为 new_val。这部分代码现在看起来像这样：

    ani_state.travel(new_val)
    while (
        ani_state.is_playing() and (
            ani_state.get_current_node() != new_val
            or ani_state.get_current_play_position()
               < ani_state.get_current_length()
        )
    ):
        yield(get_tree(), "idle_frame")

    ani_state.stop()
    staff_mode = ani_state.get_current_node()
    property_list_changed_notify()