MIPS Assembly 为什么这些寄存器加载相同的数组值？

Question

我正在尝试加载第一个和第二个位置的数组值，但由于某种原因它只加载第一个位置的值？花了一个小时试图弄清楚，但没有成功。这是我的代码。我将 $t1 设置为 0，将 $t3 设置为 4，所以我应该加载第一个和第二个值，但它只加载 $t1 和 $t3 的第一个值？

 addi $t1, $zero, 0 
 addi $t3, $zero, 4
 
 
 
 FindLessThenLoop:
 la $t1, myArray # Load first number
 addu $t1, $zero, $t1 # add offset and base together
 lw $t1, ($t1)      # fetch the data 
 
 la $t3, myArray # Load second number
 addu $t3, $zero, $t3 # add offset and base together
 lw $t3, ($t3)      # fetch the data 

Answer 1

除了使用不同的寄存器之外，第一个和第二个的代码本质上是相同的，因此，我们期望相同的结果：数组位置/索引 0 中的值。

要获取第二个元素，您可以执行以下任一操作：

la $t3, myArray     # Load second number
addiu $t3, $t3, 4   # add offset and base together
lw $t3, ($t3)       # fetch the data 

- 或 -

la $t3, myArray     # Load second number
lw $t3, 4($t3)      # fetch the data with offset 4

如果您要在循环中进行变量索引（例如 a[i]），您会更喜欢第一种形式的变体，而第二种形式用于常量索引（例如 a[1]）。

如果您有整数索引，则以下内容很有用：

# usually done outside of and before a loop:
la $t3, myArray     # Load second number

# this part done inside a loop:
sll $t4, $t2, 2     # scale the integer index by 4
addu $t4, $t3, $t4  # add base and offset
lw $t1, ($t4)       # fetch the data 

请注意以下事项：

1. 有 $t3 的预循环设置，
2. 在循环内 我们保留 $t3，以便它可以每次迭代时，
3. 我们都会根据元素的大小（4x）缩放简单整数索引。

---

另一种选择是指针，它在汇编中相当容易，但建议首先将算法转换为 C 中的指针，然后再进行汇编。

指针将基址 + 缩放偏移量的概念组合到一个变量中。指针可以递增以引用下一个元素。

---

这是一个简单的说明性循环，假设元素为正，则计算数组的最大值：

    li $t0, array # t0 is the base array address: &array[0]
    li $t1, 0     # t1 is min value variable, initially zero
    li $t2, 0     # t2 is the index, aka loop control variable call it "i"
    li $t3, 10    # where to stop with "i"

loop1:
    beq $t2, $t3, loop1End   # if "i" == 10 we're done

    sll $t4, $t2, 2          # scale index by 4 due to word-sized elements
    add $t4, $t0, $t4        # add base and scaled offset
    lw $t4, 0($t4)           # fetch element from a[i]

    ble $t4, $t1, if1End
    move $t1, $t4            # capture the new max, if larger
if1End:

    addi $t2, $t2, 1         # next index position
    j loop1

loop1End:
    ...                      # t1 holds max value from the array