Modelica：不可能使用连接器进行参数传播

Question

我正在开发一个用于模拟化学过程的（开放）Modelica 库。对于商业工具，一种常见的方法是为进料流定义一次混合物配置（例如涉及多少化学成分以及涉及哪些化学成分，如水、乙醇等），然后该信息通过流传播到所有后续的单元操作。

不幸的是，到目前为止我还没有设法使用强大的modelica语言来实现这个功能。理想的情况是对“流程”进行建模，如下所示：

package StreamTest 
  connector Stream_Port
    parameter String componentlist[:];
    Real T, p;
  end Stream_Port;

  model Feed_model
    parameter String componentlist[:];
    Stream_Port Out(componentlist = componentlist);
    Real T, p;
  equation
    Out.T = T;
    Out.p = p;
  end Feed_model;

  model Tank_model
    parameter String componentlist[:];
    Real T,p;
    Stream_Port In(componentlist = componentlist);
  equation
    In.T = T;
    In.p = p;
  end Tank_model;

  model Process
    Feed_model Feed (componentlist = {"A", "B"});
    Tank_model Tank;
  equation
    connect(Feed.Out, Tank.In);
    Feed.Out.T = 200;
    Feed.Out.p = 1;
  end Process;
end StreamTest;

当然，这个示例被精简到最本质的部分，因为“组件列表”没有做任何事情。在下一步中，“componentlist”将用于计算每个模型中的物理属性，定义分子分数的数组大小等。

传播的想法如下：

1. “componentlist”仅在 Feed_model 的实例中定义 一次。
2. “组件列表”被设置为等于连接器Stream_Port的“组件列表”。
3. 连接进料和罐，并将“成分列表”传输到罐的“输入”端口。
4. 现在是关键点：Tank 从端口“In”获取“组件列表”并将其传播到 Tank 的组件列表。组件列表比在罐内用于物理属性和阵列大小，并且也可以通过罐的某些出口传播到下一个单元。

不幸的是，这不适用于 Openmodelica，尽管没有语法错误，而且我看不到这种方法不符合的语言定义中的任何点。错误消息是：

[StreamTest: 17:5-17:38]: Failed to deduce dimension 1 of componentlist due to missing binding equation.

当然，我可以在每个单元的模型“过程”级别上定义“组件列表”：

model Process
  Feed_model Feed (componentlist = {"A", "B"});
  Tank_model Tank (componentlist = {"A", "B"});
equation
  connect(Feed.Out, Tank.In);
  Feed.Out.T = 200;
  Feed.Out.p = 1;
end Process;

但是我必须为“过程”中模型的每个实例冗余地执行此操作 -不像我想实现更大的流程模型那么优雅......

这种行为的原因：参数传播仅在模型的声明部分“向下”工作，其中所有模型都被实例化。当我们连接模型时，参数传播只能用于端口定义内的数组大小。它就被卡住了：信息没有传输到下一个连接的单元。

任何想法，如何解决这个问题？我错过了什么吗？虽然我对一些类似的商业工具很有经验，但我仍然处于 modelica 的学习曲线上......

Answer 1

AFAIK，仅靠 (Open)Modelica 是不可能做到这一点的，但一些工具已经通过自动化功能进行了修改：

Modelica 3.4 规范无法直接通过端口自动传播流体模型，但 Modelica 工具可能支持该功能。例如，在 Dymola 中，可以设置选项 Advanced.MediaPropagation=1 以应用电路中媒体模型的自动传播。

(https://build.openmodelica.org/Documentation/Modelica .Fluid.UsersGuide.ComponentDefinition.FluidConnectors.html)

Dymola 视频演示了这一点：https://www.modelon.com/propagating-replaceable-medium-automatically/

Modelica 规范问题，如果您希望将其包含在语言/重新开放讨论中：https://github.com/modelica/ModelicaSpecification/issues/240

Answer 2

在 Modelica 中，媒体模型不是通过连接传播的（我同意这是非常合乎逻辑的）。相反，它们是通过可替换包从上到下传播的。正如我所说，我知道通过连接器传播参数更加直观。但是连接的语言语义只处理值，而不处理类型，并且替换不同抽象媒体模型的能力非常重要，因为在大多数情况下，不同的媒体模型不仅仅是参数化（值变化），而是拓扑变化（类型变化）。这就是采用可替换包（类型）机制的原因。

Answer 3

我认为问题在于编译时数组大小并未在各处定义。假设您想要避免多次指定组件数量，您还可以使用 内部/外部机制：

package StreamTest
  connector Stream_Port
    parameter String componentlist[:];
    Real T, p;
  end Stream_Port;

  model Feed_model
    outer parameter Integer n_components;
    parameter String componentlist[n_components];
    Stream_Port Out(componentlist = componentlist);
    Real T, p;
  equation
    Out.T = T;
    Out.p = p;
  end Feed_model;

  model Tank_model
    outer parameter Integer n_components;
    parameter String componentlist[n_components];
    Real T,p;
    Stream_Port In(componentlist = componentlist);
  equation
    In.T = T;
    In.p = p;
  end Tank_model;

  model Process
    inner parameter Integer n_components = 3; // only define it once 
    Feed_model Feed (componentlist = {"A", "B", "C"});
    Tank_model Tank;
  equation
    connect(Feed.Out, Tank.In);
    Feed.Out.T = 200;
    Feed.Out.p = 1;
  end Process;
end StreamTest;

Answer 4

我非常感兴趣地阅读了您的帖子和讨论，我自己也曾为类似的问题而苦苦挣扎。区分 Modelica 中可以表达的内容与 Modelica 标准库的常见用法和风格非常重要。

为了举例说明 Michael Tiller 所写的有关如何通过可替换包传播媒体模型的内容，我附上了下面的代码，其中显示了一个与您的示例有些相似的示例。此处，浓度矢量为 c 的液体流 F 从 FeedTank 流向 HarvestTank，通过具有驱动该流的压差的管道。还使用了流和流的概念。您可以在 如何构造Modelica 中的液体平衡连接器？。 （注意 DEMO_v46 与使用解决方案 DEMO_v42 更新的 DEMO_v40 相同）

我不想使用术语“传播”，而是说 EquipmentLib 是使用可替换媒体包“适应”的。
传播意味着一条路径，或许还有一系列的变化，而这里整个设备库都在一个语句中进行了调整。

EquipmentLib 包含储罐、管道、传感器、泵等组件，其中实际包“Medium”（包括物质数量）称为 EquipmentLib 的形式参数。通过更改库的“介质参数”，您可以获得适合您选择的介质的所有设备。这就像我眼中你们在实践中的工作方式。例如，如果您需要建立一个处理酸性溶液的工艺，那么您从一开始就选择专门用于处理该溶液的储罐、管道、泵等。

 package DEMO_v46

 //  ---------------------------------------------------------------------------------------------
 //     Interfaces  
 //  ---------------------------------------------------------------------------------------------

     import Modelica.Blocks.Interfaces.RealInput;
     import Modelica.Blocks.Interfaces.RealOutput;

     partial package MediumBase
         constant String name                                   "Medium name";
         constant Integer nc = 1                                "Number of substances";
         replaceable type Concentration = Real[nc]              "Substance conc";       
     end MediumBase;

 //  ---------------------------------------------------------------------------------------------
 //     Medium3 specified  
 //  ---------------------------------------------------------------------------------------------

     package Medium3 
         extends MediumBase
             (name="Three component medium",
              nc=3);
         constant Real[nc] mw = {10, 20, 30}                    "Substance weight"; 
         constant Integer A = 1                                 "Substance index";
         constant Integer B = 2                                 "Substance index";
         constant Integer C = 3                                 "Substance index";
     end Medium3;

     record Medium_data
         constant String name = Medium3.name;
         constant Integer nc = Medium3.nc;
         constant Real[nc] mw = Medium3.mw;
         constant Integer A = Medium3.A;
         constant Integer B = Medium3.B;
         constant Integer C = Medium3.C;
     end Medium_data;

 //  ---------------------------------------------------------------------------------------------
 //     Equipment dependent on the medium but written in a general way 
 //  ---------------------------------------------------------------------------------------------

     package EquipmentLib
         replaceable package Medium = MediumBase         // formal parameter Medium for EquipmentLib
             constrainedby MediumBase;

         connector LiquidCon
             Real p                                              "Pressure"; 
             flow Real F (unit="m3/s")                           "Flow rate";
             stream Medium.Concentration c                       "Substance conc";
         end LiquidCon;

         model PipeType
             LiquidCon inlet, outlet; 
             parameter Real area = 1;
         equation
             inlet.F = -outlet.F;
             outlet.F = area^2*(outlet.p - inlet.p);            // Linearized Bernoulli equation
             for i in 1:Medium.nc loop
                 outlet.c[i] = inStream(inlet.c[i]);
                 inlet.c[i] = inStream(outlet.c[i]);
             end for;
         end PipeType;

        model FeedtankType
           LiquidCon outlet;                                  
             parameter Real p = 0.1                              "Pressure"; 
           parameter Real V_0 (unit="m3") = 100                "Initial feed volume";         
             parameter Real[Medium.nc] c_in (each unit="kg/m3") 
                            = {1.0*k for k in 1:Medium.nc}          "Feed inlet conc";                        
           Real V(start=V_0, fixed=true, unit="m3")            "Feed volume";
        equation    
             for i in 1:Medium.nc loop
                 outlet.c[i] = c_in[i];
             end for;
             outlet.p = p;
           der(V) = outlet.F;               
        end FeedtankType;

       model HarvesttankType
          LiquidCon inlet;
             parameter Real p = 0.0                             "Pressure";                     
           parameter Real V_0 (unit="m3") = 1.0               "Initial harvest liquid volume";
             parameter Real[Medium.nc] m_0 
                  (each unit="kg/m3") = zeros(Medium.nc)       "Initial substance mass";
             Real[Medium.nc] m 
                  (start=m_0, each fixed=true)                 "Substance mass";
             Real[Medium.nc] c                                  "Substance conc"; 
           Real V(start=V_0, fixed=true, unit="m3")           "Harvest liquid volume";
        equation
             inlet.p = p;
             inlet.c = c;
           der(V) = inlet.F;
             for i in 1:Medium.nc loop
                 der(m[i]) = actualStream(inlet.c[i])*inlet.F;
                 c[i] = m[i]/V;
             end for;               
        end HarvesttankType;
     end EquipmentLib;
  
 //  ---------------------------------------------------------------------------------------------
 //     Adaptation of package Equipment to Medium3 
 //  ---------------------------------------------------------------------------------------------

     package Equipment
         import DEMO_v46.EquipmentLib;
         extends EquipmentLib(redeclare package Medium=Medium3);
     end Equipment;

 //  ---------------------------------------------------------------------------------------------
 //     Examples of systems 
 //  ---------------------------------------------------------------------------------------------

     model Test
         Medium_data medium;
         Equipment.FeedtankType feedtank;
         Equipment.HarvesttankType harvesttank;
         Equipment.PipeType pipe;
     equation
         connect(feedtank.outlet, pipe.inlet);
         connect(pipe.outlet, harvesttank.inlet);
     end Test;

 end DEMO_v46;