选择所有表格和在 MS Word 中拆分

Question

我希望我的代码选择 MS Word 文档的所有表格并拆分所有行，但目前使用此宏，我可以拆分最后一个表格。谁能帮我修改这段代码，它现在也没有选择表格？

以下是代码：

Sub selecttables()
    Dim i As Integer    
    i = ActiveDocument.Tables.Count
    
    Set Tbl = ActiveDocument.Tables(i)
    
    Dim mytable As Table
    For Each mytable In ActiveDocument.Tables
        mytable.Range.Editors.Add wdEditorEveryone
    Next

    ActiveDocument.SelectAllEditableRanges (wdEditorEveryone)
    ActiveDocument.DeleteAllEditableRanges (wdEditorEveryone)
    
    For Each mytable In ActiveDocument.Tables
    Next

    Do While Tbl.Rows.Count > 1
        Tbl.Cell(2, 1).Range.Select
        Selection.InsertBreak Type:=wdColumnBreak '
        Set Tbl = ActiveDocument.Tables(ActiveDocument.Tables.Count)
    Loop
End Sub

Answer 1

对于您希望实现的任务来说，您的代码过于复杂。话虽如此，这项任务本身就是一项棘手的任务。

拆分表格时，会增加文档中表格的数量。因此，您需要小心引用正确的表。因此，与 Office 应用程序中对集合的许多操作一样，您必须逆向操作。

下面的代码应该可以实现您的任务（至少它可以在我的电脑上运行）。我唯一需要注意的是，如果文档中存在垂直合并的单元格，因为此代码将拆分合并的单元格，但会将文本保留在合并序列的第一行中

Option Explicit

Sub SplitTables()
    
    Dim myTableCounter As Long
    For myTableCounter = ActiveDocument.StoryRanges(wdMainTextStory).Tables.Count To 1 Step -1
    
        SplitTableToRows myTableCounter
        
        
    Next
    
End Sub


Public Sub SplitTableToRows(ByVal ipTableIndex As Long)

    With ActiveDocument.StoryRanges(wdMainTextStory).Tables.Item(ipTableIndex)
    
        Dim myRowIndex As Long
        For myRowIndex = .Rows.Count To 2 Step -1
        
            .Cell(myRowIndex, 1).Range.Select
            Selection.SplitTable
            Selection.MoveUp
            

        Next
        
    End With

End Sub