根据Powerpoint中的关键字选择幻灯片

Question

我正在尝试创建一个宏，该宏将选择标题中包含关键字的任何幻灯片，但没有任何结果。该 ppt 包括不同的首页、免责声明和内容幻灯片，其想法是向每张幻灯片的标题添加关键字，并使用宏来选择所选幻灯片并将其导出为 PDF。

我已经使导出部分正常工作，但需要手动输入幻灯片编号。

我从类似的问题中获得了下面的代码，但无法重写它以选择幻灯片而不是将答案呈现为 MsgBox。有人可以帮忙吗？

Sub FindText()
Dim sld As Slide, shp As Shape, list As String, myPhrase As String
myPhrase = InputBox("enter a phrase", "Search for what?")

For Each sld In Application.ActivePresentation.Slides
    For Each shp In sld.Shapes
        If shp.HasTextFrame Then
            If Left(shp.Name, 5) = "Title" Then
                If Not shp.TextFrame.TextRange.Find(FindWhat:=myPhrase) Is Nothing Then
                    If list = "" Then list = sld.Name Else list = list & ", " & sld.Name
                End If
            End If
        End If
    Next shp
Next sld
MsgBox list

End Sub

Answer 1

我的完整代码，使用史蒂夫的解决方案，如果有人试图解决同样的问题：

Sub SelectedSlidesToPDF()
    
  Dim sld As Slide, shp As Shape, list As String, myPhrase As String

myPhrase = "WhatYouLookFor"

    For Each sld In Application.ActivePresentation.Slides

' FIRST, hide the slide:
sld.SlideShowTransition.Hidden = True

        For Each shp In sld.Shapes
            If shp.HasTextFrame Then
                If Left(shp.Name, 5) = "Title" Then
                    If Not shp.TextFrame.TextRange.Find(FindWhat:=myPhrase) Is Nothing Then

' UNHIDE the slides that contain your keywords
sld.SlideShowTransition.Hidden = False

                End If
            End If
        End If
    Next shp
Next sld

'EXPORT slides
  ActivePresentation.ExportAsFixedFormat ActivePresentation.Path & "\" & "MySelectedSlides " & Format(DateSerial(Year(Date), Month(Date) - 1, 1), "yyyy-mm") & ".pdf", ppFixedFormatTypePDF, ppFixedFormatIntentPrint, RangeType:=ppShowAll

    
' UNIHDE all slides in presentation
For Each sld In ActivePresentation.Slides
        sld.SlideShowTransition.Hidden = msoFalse
    Next sld

End Sub

Answer 2

默认情况下，当您另存为 PDF 时，PDF 不会包含任何隐藏的幻灯片，因此您只需先隐藏所有幻灯片，然后取消隐藏要包含在 PDF 中的任何幻灯片即可。虽然我没有在这里执行此操作，但在保存为 PDF 后，您将需要再次取消隐藏所有幻灯片。

    For Each sld In Application.ActivePresentation.Slides

' FIRST, hide the slide:
sld.SlideShowTransition.Hidden = True

        For Each shp In sld.Shapes
            If shp.HasTextFrame Then
                If Left(shp.Name, 5) = "Title" Then
                    If Not shp.TextFrame.TextRange.Find(FindWhat:=myPhrase) Is Nothing Then

' UNHIDE the slides that contain your keywords
sld.SlideShowTransition.Hidden = False                        
                    End If
                End If
            End If
        
        Next shp
    Next sld