从 CombiTimeTable 加载的时间序列的最大值

Question

有没有办法从 CombiTimeTable (tableOnFile==true) 获取最大值并将其用作参数？

我希望能够在方程中使用最大值，而无需为每个组件设置最大值。想想其他人是如何处理这个问题的，我很确定这是不可能的，但在我看来应该是这样。

时间表文档没有任何迹象表明我想做的事情是可能的，但也许有人知道如何在不设置最大值参数的情况下处理这个问题。

Answer 1

支持最小/最大次数，但对于 x 值，我想您需要编写如下内容：

block CombiTimeTableWithMax
  import Modelica.Blocks.Tables.Internal;
  extends Modelica.Blocks.Sources.CombiTimeTable;
  // The min/max for time are t_minScaled etc
  final parameter Real xMin[nout](each fixed=false),xMax[nout](each fixed=false);
  function getMinMax
    input Modelica.Blocks.Types.ExternalCombiTimeTable tableID;
    input Integer nout;
    input Real p_offset[nout];
    output Real xMin[nout],xMax[nout];
  protected 
    Real t;
    Real x[nout];
  algorithm 
    t:=Internal.getTimeTableTmin(tableID);
    x:=p_offset+Internal.getTimeTableValue(tableID, 1:nout, t, t, t);
    xMin:=x;
    xMax:=x;
    while t<Internal.getTimeTableTmax(tableID) loop
      t:=Internal.getNextTimeEvent(tableID, t);
      x:=p_offset+Internal.getTimeTableValue(tableID, 1:nout, t, t, t);
      for i in 1:nout loop
        if x[i]<xMin[i] then xMin[i]:=x[i]; end if;
        if x[i]>xMax[i] then xMax[i]:=x[i]; end if;
      end for;
    end while;
  end getMinMax;
initial equation 
  (xMin,xMax)=getMinMax(tableID, nout, p_offset);
  annotation (uses(Modelica(version="4.0.0")));
end CombiTimeTableWithMax;