为什么 Clojure 允许我重新定义同一个变量？

Question

如果变量在 Clojure 中是不可变的，那么为什么它允许在下面的代码片段中重新定义相同的变量：

(ns tutorial.test-immutability-of-variables)

(defn test_if_variables_are_mutable
  []
  (def a 1)
  (def a 10)
  (println (format "Value of a: %d" a) )
  )

(test_if_variables_are_mutable)

上面的代码编译并且 o/p 是 10。

Answer 1

Clojure 区分值和对值的引用。 Clojure 保证值是不可变的。

考虑一下当你的函数被求值时会发生什么：

(def a 1)

当上面的形式被求值时，会创建一个 Clojure Var（名称为 a 和命名空间 tutorial.test-immutability-of-variables ) 并且它绑定到值 1。

(def a 10)

当计算此形式时，现有的 Clojure Var 会反弹到值 10。

强烈建议不要在函数中使用 def。仅在代码中对顶级表单使用 def。或者，对于词法绑定符号，请使用 let。

所发生的事情的完整情况比我上面概述的要复杂一些，请参阅参考文档在瓦尔斯上。 Clojure 中还有其他引用类型，例如 Atoms。

Answer 2

正如另一个答案指出的那样，您可以更改全局 Var 指向的内容，但无法更改原始值。这是另一个示例：

(def x 42)

(defn changer-1
  []
  (println "changer-1: x - old" x)
  (let [x "Goodbye"] ; change a local variable
    (println "changer-1: x - new" x)))

(defn caller-1
  []
  (newline)
  (let [x "Hello"]
    (println "caller-1: x - before" x)
    (changer-1)
    (println "caller-1: x - after " x)))

(defn changer-2
  []
  (println "changer-2: x - old" x)
  (def x 666) ; reset the global Var (normally bad form)
  (println "changer-2: x - new" x))

(defn caller-2
  []
  (newline)
  (println "caller-2: Var x - before" x)
  (let [x "Hello"]
    (println "caller-2: x - before" x)
    (changer-2)
    (println "caller-2: x - after " x))
  (println "caller-2: Var x - after" x))


(caller-1)
(caller-2)

有关结果的

-----------------------------------
   Clojure 1.10.3    Java 15.0.2
-----------------------------------

caller-1: x - before Hello
changer-1: x - old 42
changer-1: x - new Goodbye
caller-1: x - after  Hello

caller-2: Var x - before 42
caller-2: x - before Hello
changer-2: x - old 42
changer-2: x - new 666
caller-2: x - after  Hello
caller-2: Var x - after 666

更多信息，请参阅此文档列表 来源，特别是“Getting Clojure”和“Brave Clojure”