Haskell 如何“脱糖”？ getline 在这个 do 块中？

Question

我读过几本关于 Haskell 的书，但还没有编写太多代码，而且我对 Haskell 在某种情况下所做的事情有点困惑。假设我正在使用 getLine，以便用户可以按某个键继续，但我真的不想以任何有意义的方式解释该人的输入。我相信这是执行此操作的有效方法：

main = do
    _ <- getLine
    putStrLn "foo"

我了解其正在执行的操作的基本要点。 getLine 返回一个 IO String，putStrLn 接受一个 String 并返回 IO () >，所以如果理论上我想打印用户在控制台中输入的内容，我基本上会使用 Monad 类中的 >>= 运算符。就我而言，我相信我的代码相当于 getLine >>> putStrLn "foo" 因为我放弃了 getLine 的返回值。

但是，如果我这样做怎么办？

main = do
    let _ = getLine
    putStrLn "foo"

在本例中，我们正在设置一种 lambda 来处理需要 IO String 的东西，对吗？我可以编写一个 printIOString 函数来打印用户的输入，这样就可以正常工作。然而，当我实际上没有使用该 IO String 时，程序的行为很奇怪...... getLine 甚至不提示我输入；程序只是打印出“foo”。

我不太确定这里的“脱糖”语法是什么，或者这是否会揭示 Haskell 在幕后所做的事情。

Answer 1

让我们用几个更复杂的例子来热身一下。

main = do
    x
    x
    x
    putStrLn "foo"
    where
    x = do
        getLine

您希望这能起到什么作用？我不了解你的情况，但我期望程序得到三行，然后打印一些东西。如果我们对第二个 do 块进行脱糖，我们会得到

main = do
    x
    x
    x
    putStrLn "foo"
    where x = getLine

因为这是对另一个块的脱糖，所以它的行为是相同的，在打印之前得到三行。如果您觉得第一个思路不直观，那么还有另一种思路可以得出相同的答案。 “引用透明性”是 Haskell 的定义特性之一，它的意思就是你可以用它的定义替换对某事物（即变量名）的“引用”，因此前面的程序应该与

main = do
    getLine
    getLine
    getLine
    putStrLn "foo"

我们的 程序完全相同。正在认真对待等式x = getLine。好的，我们有一个读取三行并打印的程序。这个呢？

main = do
    x
    x
    putStrLn "foo"
    where x = getLine

得到两行并打印。还有这个？

main = do
    x
    putStrLn "foo"
    where x = getLine

获取一行然后打印。希望您明白这是怎么回事...

main = do
    putStrLn "foo"
    where x = getLine

获取零行然后打印，即立即打印！我使用 where 而不是 let 来使开头的示例更加明显，但是您几乎总是可以将 where 块替换为其 < code>let 表亲而不改变其含义：

main = let x = getLine in do
    putStrLn "foo"

由于我们不引用 x，我们甚至不需要命名它：

main = let _ = getLine in do
    putStrLn "foo"

这是您编写的代码的脱糖。

Answer 2

第一种情况按照您的预期脱糖：

main = getLine >>= \_ -> putStrLn "foo"

相当于

main = getLine >> putStrLn "foo"

在第二种情况下，

main = do
    let _ = getLine
    putStrLn "foo"

脱糖为

main = let _ = getLine in putStrLn "foo"

因为不需要 _ = getLine 值来计算 let 表达式，编译器可以随意忽略它，并且永远不会执行 IO 效果，这就是为什么不再提示您进行 CLI 输入的原因。

尽管这两种情况都忽略了 getLine 的结果，但区别在于第一种情况在 IO 上下文中计算 getLine，而第二种情况则计算 >getLine 作为纯值。在 IO 中，副作用必须一起执行和排序，但在纯上下文中，编译器可以自由地忽略未使用的值。

我不建议这样做，因为它不是很惯用，但您可以编写类似的内容

printIOString :: IO String -> IO ()
printIOString ios = ios >>= putStrLn

并像 printIOString getLine 一样使用它

Answer 3

根据 https://stackoverflow.com/tags/do-notation/info，

do { let { _ = getLine } ; putStrLn "foo" } 
= 
do { let { _ = getLine } in putStrLn "foo" } 
= 
     let { _ = getLine } in putStrLn "foo"

Haskell 语义是等效的到

    getLine & (\ _ -> putStrLn "foo")
=
                      putStrLn "foo"

（使用x & f = f x），而实际上

do { _ <- getLine ; putStrLn "foo" }
=
  getLine >>= (\ _ -> putStrLn "foo")

这不能进一步简化。