AWS S3 存储桶的 Terraform 文件不断收到错误：提供程序配置无效

Question

编辑：我现在已经修改了问题以显示整个 main.tf 文件。

我有一个应该创建 AWS S3 存储桶的 Terraform 文件，但每次运行 terraform plan 时不断收到的错误之一是：

│ Error: Invalid provider configuration
│ Provider "registry.terraform.io/hashicorp/aws" requires explicit configuration. Add a provider block to the root module and configure the provider's required arguments as described in the provider documentation.

The main.tf file:

terraform {
    backend  "s3" {
    region         = "us-east-1"
    bucket         = "bucketname"
    key            = "path/terraform.tfstate" 
    dynamodb_table = "tf-state-lock" 
    access_key = "<access_key>"
    secret_key = "<secret_key"
    }

    required_providers {
      aws = {
        version = " ~> 3.0"
        source = "registry.terraform.io/hashicorp/aws"
      }
    }

} 

provider "aws" {
  alias  = "east" 
  region = "us-east-1"
  access_key = "access_key"
  secret_key = "secret_key"
}

resource "aws_s3_bucket" "tf-remote-state" {
  bucket = "bucketname" 

  versioning {
    enabled = true
  }

  lifecycle {
    prevent_destroy = true
  }
}

resource "aws_dynamodb_table" "dynamodb-tf-state-lock" {
  name            = "tf-state-lock" 
  hash_key        = "LockID"
  read_capacity   = 20
  write_capacity = 20

  attribute {
    name = "LockID"
    type = "S"
  }

  tags = {
    name = "state lock"
  }
} 

What am I do bad 我做错了什么？

Answer 1

由于您在 provider 块中使用 alias [1]，当前设置资源的方式将导致 Terraform 期望使用无别名的 provider 阻止您要创建的资源存在：

默认情况下，资源使用从资源类型名称的第一个单词推断出的默认提供程序配置（没有别名参数的配置）。

换句话说，由于您没有在两个资源块（对于 S3 和 DynamoDB）中指定别名提供程序的名称，Terraform 希望默认使用非别名提供程序配置。由于您没有没有 alias 的提供程序块，因此修复它的最简单方法可能是将以下内容添加到两个资源块 [2]：

provider = aws.east

整个块将如下所示：

resource "aws_s3_bucket" "tf-remote-state" {
  provider = aws.east
  bucket   = "bucketname" 

  versioning {
    enabled = true
  }

  lifecycle {
    prevent_destroy = true
  }
}

resource "aws_dynamodb_table" "dynamodb-tf-state-lock" {
  provider        = aws.east
  name            = "tf-state-lock" 
  hash_key        = "LockID"
  read_capacity   = 20
  write_capacity = 20

  attribute {
    name = "LockID"
    type = "S"
  }

  tags = {
    name = "state lock"
  }
}

但是，如果没有任何特殊原因需要使用别名（即无论如何都会在一个区域中创建资源），则仅设置 region （就像您已经做的那样）也可以解决问题。如果您不想使用别名，只需从 provider 块中删除 alias = "east" 即可，然后您无需更改资源块中的任何内容，该代码将按原样工作。

---

[1] https://www.terraform.io/language/提供商/配置#alias-multiple-provider-configurations

[2] https://www.terraform.io/language/providers/configuration#selecting -备用提供商配置

Answer 2

我来自谷歌寻找

提供商“registry.terraform.io/hashicorp/aws”需要显式配置。

这就是它的修复方式：要么将此行添加到您的 main.tf 中：

provider "aws" {
  region = "eu-central-1"
}

或者定义一个环境变量：

AWS_REGION=eu-central-1