如何检查两个不同海龟品种的变量是否匹配？

Question

我正在尝试根据共享变量将乌龟移向它的后代。在我最初的代码中，我要求具有展示但没有凉亭的雄性（品种）通过孵化来建立凉亭（不同品种）。我使用 create-link-with myself 来让雄性和凉亭共享一个名为 Bird-id 的变量。

to establish-bower
  ask males[
   if has-bower? = false[
     if has-display? = true[
        hatch 1 [
        set breed bowers
        set color yellow
        set bower-id who
        set shape "house"
        create-link-with myself
        ]
           ]
      ]
    ]
end

在我的代码的第二部分中，我要求拥有凉亭和展示台的雄性返回凉亭。如果它们与自己的凉亭的距离大于 0，则雄性面向该凉亭并向前移动 1。如果距离为 0，则调整其他两个变量和能量，并且雄性会稍微随机移动。

to return-to-bower
  ask males[
    if has-bower? = true[
      if has-display? = true[
        (ifelse
        distance one-of bowers with [bird-id = (bird-id of myself)] > 0[
          face one-of bowers with [bird-id = (bird-id of myself)]
          fd 1]
        distance one-of bowers with [bird-id = (bird-id of myself)] = 0[
          set has-display? false
          set nr-display nr-display + 1
          rt random 50
          lt random 50
          fd 1
          set energy energy - 3])
      ]
    ]
  ]
end

我在编码识别凉亭属于制造它的男性的部分时遇到了困难。到目前为止，

bowers with [bird-id = (bird-id of myself)]

这显然不起作用，但它传达了我想做的事情。

我该如何写这部分？

Answer 1

我认为你的bird-id没有按预期在你的雄性和凉​​亭之间共享 - 在external-bower中你有一行设置 Bower-id who，但其中的 who 应该在凉亭的上下文中，而不是男性的上下文中。因此，male 0 可能会要求 Bower 4 将其 Bird id 设置为 4，而不是 0。如果您想使用该选项（这当然是可行的），我认为您需要更改为 set Bower-id [who] of myself - 这反映了您对 create-link-with myself 行所做的操作。

但是，如果您已经在使用链接，您可能需要使用现有链接的替代方案。 other-end 原语返回代理在提问海龟拥有的链接的另一端（在该链接中有更好的解释）。因此，只要让乌龟弄清楚哪个凉亭是它自己的，就让它查询关联链接。例如：

breed [ males male ]
breed [ bowers bower ]

males-own [ has-bower? go-time? ]

to setup
  ca
  ask n-of 10 patches [
    sprout-males 1 [
      set go-time? true
      set has-bower? false
    ]
  ]
  ask males [
    establish-bower
  ]
  reset-ticks
end

to establish-bower
  if not has-bower? [
    hatch-bowers 1 [
      set shape "house"
      create-link-with myself
    ]    
    set has-bower? true
  ]  
end

to go 
  ask males with [has-bower?] [
    ifelse go-time? [
      rt random 60 - 30 
      fd 1
      if random-float 1 < 0.05 [
        set go-time? false
      ]
    ] [
      let my-bower [other-end] of one-of my-links
      ifelse distance my-bower > 1 [
        face my-bower
        fd 1
      ] [
        move-to my-bower
        if random-float 1 < 0.02 [
          set go-time? true
        ] 
      ]
    ]
  ]
  tick 
end

我在上面使用 let 来让 bowers 仅由 males 临时检查 - 您也可以通过使用males-own 变量类似于 my-bower 并将凉亭直接分配给该变量，然后雄性将永久跟踪它。