Lambda Web API 对于除 POST 之外的动词返回 403

Question

我使用内置模板创建了无服务器 Lambda Web API。 Web api 使用 CloudFormation 部署到 AWS，一切正常（即所有 GET、POST 等）。

然后，我检查了 CloudFormation 创建的资源，并使用 Terraform 创建了所有资源。我已经仔细检查过，API 网关、Lambda 中的 REST API、Lambda 权限和触发器在从无服务器模板和 terraform 脚本创建时完全相同。

问题是，当使用从 Terraform 创建的资源时，我无法使用 POST 之外的 HTTP 动词调用 Web API。下面是我的 API 网关 terraform 脚本。

resource "aws_api_gateway_rest_api" "SimulationServer_api_gateway_rest" {
  name        = "SimulationServer"
  description = "Terraform Serverless Application Example"
}

resource "aws_api_gateway_resource" "api_gw_proxy_resource" {
  rest_api_id = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  parent_id   = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.root_resource_id
  path_part   = "{proxy+}"
}

resource "aws_api_gateway_method" "api_gw_proxy_method" {
  rest_api_id   = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  resource_id   = aws_api_gateway_resource.api_gw_proxy_resource.id
  http_method   = "ANY"
  authorization = "NONE"
}

resource "aws_api_gateway_integration" "api_gw_proxy_integration" {
  rest_api_id = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  resource_id = aws_api_gateway_method.api_gw_proxy_method.resource_id
  http_method = aws_api_gateway_method.api_gw_proxy_method.http_method
  integration_http_method = "ANY"
  type                    = "AWS_PROXY"
  uri                     = aws_lambda_function.SimulationServer.invoke_arn
}

resource "aws_api_gateway_method" "api_gw_proxy_root_method" {
  rest_api_id   = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  resource_id   = 
aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.root_resource_id
  http_method   = "ANY"
  authorization = "NONE"
}

resource "aws_api_gateway_integration" "api_gw_proxy_root_integration" {
  rest_api_id = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  resource_id = aws_api_gateway_method.api_gw_proxy_root_method.resource_id
  http_method = aws_api_gateway_method.api_gw_proxy_root_method.http_method
  integration_http_method = "ANY"
  type                    = "AWS_PROXY"
  uri                     = aws_lambda_function.SimulationServer.invoke_arn
}

resource "aws_api_gateway_deployment" "api_gw_deployment" {
  depends_on = [
    aws_api_gateway_integration.api_gw_proxy_integration,
    aws_api_gateway_integration.api_gw_proxy_root_integration,
  ]
  rest_api_id = aws_api_gateway_rest_api.SimulationServer_api_gateway_rest.id
  stage_name  = var.env
}

output "base_url" {
  value = aws_api_gateway_deployment.api_gw_deployment.invoke_url
}

Answer 1

事实证明这是一个非常奇怪但简单的解决方案。
而不是使用

integration_http_method = "ANY"

当我使用时，

integration_http_method = "POST"

它开始适用于所有 HTTP 动词（GET、POST、PUT 等），