Mule 根据类别压缩数据

Question

下面的例子。我有一组帐号和帐户属性。对于每个 account_number 都有三个类别，我希望根据 DataWeave 中的每个余额计算每个帐号的总和。

数据输入

[
    {
        Account_Number: 1,
        Account: 5,
        Category: "A",
        Balance: 500
    },
    {
        Account_Number: 1,
        Account: 5,
        Category: "A",
        Balance: 700
    },
    {
        Account_Number: 1,
        Account: 5,
        Category: "B",
        Balance: 300
    },
    {
        Account_Number: 1,
        Account: 5,
        Category: "C",
        Balance: 100
    },
    {
        Account_Number: 2,
        Account: 10,
        Category: "B",
        Balance: 300
    },
    {
        Account_Number: 2,
        Account: 10,
        Category: "B",
        Balance: 800
    }
]

数据输出

[
    {
        Account_Number: 1,
        Account: 5,
        CategoryA_Balance: 1200,
        CategoryB_Balance: 300,
        CategoryC_Balance: 100
    }
    {
        Account_Number: 2,
        Account: 10,
        CategoryA_Balance: 0,
        CategoryB_Balance: 1100,
        CategoryC_Balance: 0
    }
]```

Answer 1

我认为类别是动态的。如果没有，您可以用静态数组替换类别变量。

%dw 2.0
output application/json
var byAcctNbr = payload groupBy ($.Account_Number)
var categories = payload..Category distinctBy $
---
keysOf(byAcctNbr) map ((acctNbr) -> 
    do {
        var item = byAcctNbr[acctNbr] 
        var outItem = (item[0] default {}) - "Balance" - "Category"

        var balances = categories reduce ((category, acc={}) ->
            do {
                var accounts = item filter ($.Category == category)
                ---            
                acc ++ (
                        ("Category" ++ category ++ "_Balance"): if (isEmpty(accounts)) 0 
                                                                else sum (accounts.Balance)
                    )

        })
        ---
        outItem ++ balances
    }
)

Answer 2

与 sudhish 类似的解决方案。分解解决方案以更好地理解

distinctBy 因为 .. 将为您提供输入中存在的所有类别。 DistinctBy 将删除重复项，您将有 [A,B,C]

groupBy 根据每个帐号的详细信息进行分组

(item[0] - "Balance" - "Category")< /code> 由于我们只需要 AccountNumber 和 Account 一次，因此使用 item[0] 和“-”来消除 Balance 和 Category，因为我们需要进一步执行一些基于条件的逻辑

pluck 来转换带有 account 的对象数字作为数组的键

map 迭代每个帐号的详细信息

map 遍历类别将产生两个帐号的 [A,B,C]

filter检查顶级映射中存在的类别是否与变量中存在的类别匹配。 if (true) then sum(Balance) else 0

sum 根据使用过滤器匹配的类别进行添加

%dw 2.0
output application/json
var categories = payload..Category distinctBy $
--- 
payload groupBy $.Account_Number pluck $ map(item,index)->{
    (item[0] - "Balance" - "Category"),
    (categories map (cat)->{
        ("Category" ++ cat ++ "_Balance"):
            if (isEmpty(item filter ($.Category == cat)))
                 0
            else
               sum((item filter ($.Category == cat)).Balance)
    })
}