从同一文件中定义的包导入符号

Question

我希望我可以做这样的事情：

p.pl ：

package Common;
use strict;
use warnings;
use experimental qw(signatures);
use Exporter qw(import);
our @EXPORT = qw(NA);
sub NA() { "NA" }


package Main;
use feature qw(say);
use strict;
use warnings;
use experimental qw(signatures);
Common->import();
say "Main: ", NA();
my $client = Client->new();
$client->run();


package Client;
use feature qw(say);
use strict;
use warnings;
use experimental qw(signatures);
Common->import();
sub run($self) {
    say "Client: ", NA();
}
sub new( $class, %args ) { bless \%args, $class }

在同一文件中的两个包之间共享公共符号。然而运行这个脚本会给出：

$ perl p.pl
Main: NA
Undefined subroutine &Client::NA called at ./p.pl line 30.

我在这里缺少什么？

Answer 1

问题是您

$client->run();

之前

Common->import();

---

调用了A simple way to inline module:

BEGIN {
    package Common;
    use strict;
    use warnings;
    use experimental qw(signatures);
    use Exporter qw(import);
    our @EXPORT = qw(NA);
    sub NA() { "NA" }
    $INC{"Common.pm"} = 1;
}

然后您可以正常使用 use Common; 。

它并不完美。像 App::FatPacker 这样连接到 @INC 确实可以提供最佳结果。但这会让你的生活更轻松。