“不是哈希引用”创建多维散列（其键能够存储多个值）时，perl 中出现错误

Question

我正在尝试创建一个多维哈希，其键作为数组，以便相同的键可以存储多个值，并且不会被覆盖。

下面是代码片段：

my %hashR;
my @RelDiv = qw(15.4 dev ques 15.4 dev ques2 15.4 dev2 ques1 15.4 dev2 ques2 
                15.2 dev3 ques2); 
while (my $RName = shift @RelDiv) {
    my $ProStr = shift @RelDiv;
    push @{$hashR{$RName}}, $ProStr;
    my $BName = shift @RelDiv ;    ## Working file till here (tried printing the values)
    push @{$hashR{$RName}{$ProStr}}, $BName;   ###### Error on this line
}

我想要的结构如下：

{
      '15.4' => {
                   
                   'dev' => [
                                'ques',
                                'ques2'
                            ]
      
                  'dev2' => [
                               'ques1',
                               'ques2'
                             ]
                  
                },
       '15.2' => {
                   'dev3' => [
                                'ques2'
                            ]             
                }

};

但是，我收到错误“不是 file1.pl 行的哈希引用”。任何人都可以帮助解决该错误吗？

谢谢

Answer 1

当你这样做时，你创建了一个数组引用：

push @{$hashR{$RName}}, $ProStr;
# means: $hashR{$RName} = [ $ProStr ]

然后当你这样做时，你尝试将它用作哈希引用：

push @{ $hashR{$RName}{$ProStr} }, $BName;   ###### Error on this line
#                    ^^^-- here

很难说出你想要的结构是什么样子，所以我不能真正帮助你提供建议。也许如果你解释一下你想要实现的目标，我可以提供帮助。

---

随着新结构的更新，这是一种简单的方法来实现

use strict;
use warnings;
use Data::Dumper;

my %hash;
my @RelDiv = qw(15.4 dev ques 15.4 dev ques2 15.4 dev2 ques1 15.4 dev2 ques2 15.2 dev3 ques2); 

while (@RelDiv) {
    my ($RName, $ProStr, $BName) = splice @RelDiv, 0, 3;
    push @{ $hash{$RName}{$ProStr} }, $BName;
}
print Dumper \%hash;

输出（数据结构）：

$VAR1 = {
          '15.4' => {
                      'dev2' => [
                                  'ques1',
                                  'ques2'
                                ],
                      'dev' => [
                                 'ques',
                                 'ques2'
                               ]
                    },
          '15.2' => {
                      'dev3' => [
                                  'ques2'
                                ]
                    }
        };

但是，以下批评仍然存在。您没有透露有关数据收集的信息，并且使用数组中的 splice 解决方案并不是很好。您应该返回上一步，谈谈您的数据收集。

不过，这并不是创建哈希的好方法。如果您只是想在开始时将值列表分配给数组，请立即将其分配给散列，并且不要将这种奇怪的转换转换为另一个结构。或者，如果您像我怀疑的那样，再次读取文件，请立即创建哈希结构。如果您提供更多详细信息，我可以提供更好的建议。