如何获取groovy中嵌套地图的差异？

Question

如何获取嵌套地图的差异？我不知道如何得到它。在我的地图中有 2 个元素：response1 和response2。在response1中，它的size()为5，在response2中，它的size()为3。我想打印出每个元素和缺失元素的差异

我的代码：

def map = [response1:[[code:PLACE1, date:20-Jan-2021,
[code:PLACE2, date:20-Feb-2021],
[code:PLACE3, date:20-Mar-2021],
[code:PLACE4, date:20-Apr-2021],
[code:PLACE5, date:20-May-2021]],
response2:[[code:PLACE1, date:21-Jan-2021,
[code:PLACE2, date:20-Feb-2021],
[code:PLACE3, date: 20-Mar-2021]]]


def diff1 = map['response1'].minus(map['response2'])
def diff2 = map['response2'].minus(map['response1'])

echo "${diff1}\n"
echo "${diff2}\n"

实际输出：

[[code:PLACE2, date:20-Feb-2021],
[code:PLACE4, date:20-Apr-2021],
[code:PLACE5, date:20-May-2021]]


[[code:PLACE2, date:20-Feb-2021],
[code:PLACE3, date: 20-Mar-2021]]

预期输出：

[[date:20-Jan-2021],
[code:PLACE4, date:20-Apr-2021],
[code:PLACE5, date:20-May-2021]] 

[[date:21-Jan-2021],

Answer 1

我相信您所追求的是某种可用于嵌套地图和列表的 minus 函数。这是一种使用递归产生预期结果的方法。

def minus(left, right) {
    if (left == right) {
        assert left in Map || left in List
        return left.getClass().getDeclaredConstructor().newInstance()
    } else {
        switch (left) {
            case Map:
                if (!(right instanceof Map)) {
                    return left
                } else {
                    return left.findAll { k, v -> !right.containsKey(k) } \
                           + left.findAll { k, v -> right.containsKey(k) && v != right[k] }
                                    .collectEntries { k, v -> [k, minus(v, right[k])] }
                }
            case List:
                if (!(right instanceof List)) {
                    return left
                } else {
                    return left.withIndex().with {
                        it.findAll { val, index -> index < right.size() && val != right[index] }
                                .collect { val, index -> minus(val, right[index]) } \
                        + it.findAll { val, index -> index >= right.size() }
                                .collect { val, index -> val }
                    }
                }
            default:
                return left
        }
    }
}

def response1 = [[code: "PLACE1", date: "20-Jan-2021"],
                 [code: "PLACE2", date: "20-Feb-2021"],
                 [code: "PLACE3", date: "20-Mar-2021"],
                 [code: "PLACE4", date: "20-Apr-2021"],
                 [code: "PLACE5", date: "20-May-2021"]]

def response2 = [[code: "PLACE1", date: "21-Jan-2021"],
                 [code: "PLACE2", date: "20-Feb-2021"],
                 [code: "PLACE3", date: "20-Mar-2021"]]

assert minus(response1, response2) == [['date': '20-Jan-2021'], ['code': 'PLACE4', 'date': '20-Apr-2021'], ['code': 'PLACE5', 'date': '20-May-2021']]
assert minus(response2, response1) == [['date': '21-Jan-2021']]