如何检查序言中每个数字的位置值？

Question

toword(0,'zero').
toword(1,'one').
toword(10,'ten').
toword(15,'fifteen').
toword(30,'thirty').
toword(100,'one hundred').
toword(500,'five hundred').
toword(2000,'two thousand).

pv(X,[]).
//pv(X , [H|T) :- toword(X/10, T), pv(???  I know this is wrong.

我试图获取每个位置的值并将其放入列表中。例如; X = 2531 列表将是 [2000,500,30,1]。我没有列出所有的 toword() 事实，但还会有更多。我不知道如何获得该数字的每个位值。

Answer 1

将整数转换为其英语口语形式是一个比您想象的更困难的问题。

您需要做的第一件事是将您的值划分为 3 位数字组的列表（其正确名称是句点）：

groups( 0 , Gs , Gs ) .
groups( N , Ts , Gs ) :- N > 0, div_rem(N,1000,Q,R), groups(Q,[R|Ts],Gs).

div_rem(X,Y,Q,R) :-
    Q is X div Y,
    R is X rem Y.

这将变成一个整数，例如 1234567890 像这样的东西

[ 1, 234, 567, 890 ]

会根据组相对于列表右侧的位置为您提供正确的后缀：

period( 2, thousand    ).
period( 3, million     ).
period( 4, billion     ).
period( 5, trillion    ).
period( 6, quadrillion ).
period( 7, quintillion ).
period( 8, sextillion  ).

唯一真正棘手的部分是弄清楚如何处理第一个/最右边的这样的句点 （数百）。 0-99 之间的数字是有问题的：

• 值 0-19 是不规则的形式，
• 值 20-99 是绝对规则的，并且由十年的名称组成（二十< /code>、三十等），附加一个-，然后在个位附加数字名称。

这些是特殊数字：

special(  0, zero       ).
special(  1, one        ).
special(  2, two        ).
special(  3, three      ).
special(  4, four       ).
special(  5, five       ).
special(  6, six        ).
special(  7, seven      ).
special(  8, eight      ).
special(  9, nine       ).
special( 10, ten        ).
special( 11, eleven     ).
special( 12, twelve     ).
special( 13, thirteen   ).
special( 14, fourteeen  ).
special( 15, fifteen    ).
special( 16, sixteen    ).
special( 17, seventeen  ). 
special( 18, eighteen   ).
special( 19, nineteen   ).
special( 20, twenty     ).
special( 30, thirty     ).
special( 40, forty      ).
special( 50, fifty      ).
special( 60, sixty      ).
special( 70, seventy    ).
special( 80, eighty     ).
special( 90, ninety     ).

以下是如何构造 0 到 999 之间的任何数字的名称：

group_name( 0 , Ws , Ws ) :- !.
group_name( N , Ws , W1 ) :-
    div_rem(N,100,Q,R),
    hundreds(Q,Ws,W0),
    tens_and_ones(R,W0,W1).
                 
hundreds( 0 , Ws              , Ws ).
hundreds( N ,  [W,hundred|W0] , W0 ) :- N > 0, special(N,W).

tens_and_ones( N ,     [W|Ws] , Ws ) :- special(N,W), !.
tens_and_ones( N , [W1-W2|Ws] , Ws ) :-
    Ones is N rem 10,
    Tens is N - Ones,
    special(Tens,W1),
    special(Ones,W2).

一旦有了这个名称，其他一切就很容易了。这只是跟踪您当前正在处理的时间段并附加正确的后缀的问题

int_words( N , _             ) :- \+ integer(N), !, fail.
int_words( N , [negative|Ws] ) :- N <  0, X is abs(N), number_phrase(X,Ws).
int_words( N ,           Ws  ) :- N >= 0,              number_phrase(N,Ws).

number_phrase(N,Ws) :-
    groups(N,[],Gs),
    length(Gs,P),
    groups_to_words(Gs,P,Ws).

groups_to_words( [G]    , _ , Ws ) :-
    group_name(G,Ws,[]).
groups_to_words( [G|Gs] , P , Ws ) :-
    period(P,Sfx),
    group_name(G,Ws,[Sfx|W1]),
    P1 is P-1,
    groups_to_words(Gs,P1,W1).

您可以在 https://swish.swi-prolog.org/p/int-words.pl

Answer 2

toword(0, 'zero').
toword(1, 'one').
toword(10, 'ten').
toword(15, 'fifteen').
toword(30, 'thirty').
toword(100, 'one hundred').
toword(500, 'five hundred').
toword(2000, 'two thousand').

to_words(N, Lst) :-
    to_words_(N, Lst).

to_words_(N, Lst) :-
    % Using compare, to prevent unwanted choicepoint
    compare(Comp, N, 0),
    to_words_comp_(Comp, N, Lst).

to_words_comp_(=, 0, []).
to_words_comp_(>, N, [Text|Lst]) :-
    toword_min(N, TextN, Text),
    N0 is N - TextN,
    % Loop until zero is reached
    to_words_(N0, Lst).

toword_min(N, TextN, Text) :-
    toword(TextN, Text),
    TextN =< N,
    % Ensure this is the most fitting number to use
    \+ (toword(TextNOther, _), TextNOther =< N, TextNOther > TextN),
    % No need to search for multiple answers
    !.

swi-prolog 中的结果：

?- time(to_words(2531, Lst)).
% 286 inferences, 0.000 CPU in 0.000 seconds (97% CPU, 1656013 Lips)
Lst = ['two thousand','five hundred',thirty,one].