特定点的 JSONata 字符串操作

Question

给定这样的数组，

$s := [
"aString 1",
"bString",
"test",
"test 2",
"window 1",
"window 2",
"Garage",
"Sport",
"cString",
"etc"
]

我需要一个带有逗号分隔数组元素的字符串。
但是，子字符串的总长度不得超过 30。在这些点上，必须使用分号来代替逗号。

通过一个简单的操作，

$s ~> $join(',') 

我得到

"aString 1,bString,test,test 2,window 1,window 2,Garage,Sport,cString,etc"

这里第 4 个和第 7 个逗号必须用分号替换，因为否则这些部分将 >= 30 像这样

"aString 1,bString,test,test 2;window 1,window 2,Garage;Sport,cString,etc"

JSONata 字符串函数是否有可能？

我尝试过使用这样的 $map() 函数：

(
$result := "";
 
$map($s , function($v){
      $result := $result & $v & ($length($result) < 30 ? ',' : ';')
});
)

但这不起作用。 $result 的操作仅在函数内有效。 我怎么能这么做呢？

Answer 1

您可以使用 $reduce 将数组转换为字符串。归约操作连接字符串。诀窍是不仅要减少为字符串，还要减少为包含长度计数器和连接结果的对象：

{
  "count": chars since the last ;
  "result": the concatenated string
}

以下是表达式：

(
    /* initial reduce value: count 0 with empty string */
    $init := {
        "count": 0,
        "result": ""
    };
    /* $ is the input array */
    $reduce($, function($i, $j){
        /* $i is the count / result object, $j is the current array string */ 
        $i.count + 1 + $length($j) >= 30 ?
            /* too long, use ; and reset the length */
            {
                "count": $length($j),
                "result": $i.result & ";" & $j
            }
        :
            $i.count = 0 ? 
                /* happens only in the very beginning, avoid leading , */
                {
                    "count": $length($j),
                    "result": $j
                }
            :
                /* append using , */
                {
                    "count": $i.count + 1 + $length($j),
                    "result": $i.result & "," & $j
                }
    }, $init);
).result