VBA批量更新带有Excel链接的MS Word文件的文件夹

Question

我有一个充满 MS Word 文档的文件夹，所有文档都具有相同的标题，其中包含几个链接到 Excel 文件的字段，用于在一个位置控制项目阶段和发布日期。

我正在尝试找出一种方法，使用 VBA 循环遍历此文件夹中的所有单词文档，打开它们，更新字段，保存并关闭以避免逐一遍历并手动执行。

这里是 VBA 的新手，不太确定我在做什么（或做错了什么）。这是我迄今为止根据我看到的与此任务相关的响应拼凑而成的代码。对于如何改进/解决问题的任何帮助，我们表示赞赏。如果有帮助的话，很乐意提供更多信息。

在“Set oWordDoc = oWordApp.Documents.Open(sFileName)”行上收到错误“未设置对象变量或 With 块变量”

谢谢！

更新：感谢大家的帮助，下面添加了工作代码。

Sub Sample()
Dim oWordApp As Object, oWordDoc As Object, rngStory As Object
Dim sFolder As String, strFilePattern As String
Dim strFileName As String, sFileName As String

'> Change this to the folder which has the files
sFolder = Dir(Range("A20").Value)

'> This is the extention you want to go in for
strFilePattern = "*.doc"

'> Establish Word application object
On Error Resume Next
Set oWordApp = GetObject(, "Word.Application")

If Err.Number <> 0 Then
    Set oWordApp = CreateObject("Word.Application")
End If
Err.Clear
On Error GoTo 0

oWordApp.Visible = True

'> Loop through the folder to get the word files
strFileName = Dir$(sFolder & strFilePattern)
Do Until strFileName = ""
    sFileName = sFolder & strFileName

    '> Open the word doc
    Set oWordDoc = oWordApp.Documents.Open(sFileName)

    '> Update Fields
   
     oWordDoc.Fields.Update
        


    '> Close the file after saving
    oWordDoc.Close SaveChanges:=True

    '> Find next file
    strFileName = Dir$()
Loop

'> Quit and clean up
oWordApp.Quit

Set oWordDoc = Nothing
Set oWordApp = Nothing
End Sub

更新的工作代码：

Sub UpdateSpecHeaders()
Dim oWordApp As Object, oWordDoc As Object
Dim sFolder As String, strFilePattern As String
Dim strFileName As String, sFileName As String

'> Folder containing files to update
sFolder = Range("A20").Value


    '> Identify file extension to search for
strFilePattern = "*.doc"


'> Establish a Word application object
On Error Resume Next
Set oWordApp = GetObject(, "Word.Application")

If Err.Number <> 0 Then
    Set oWordApp = CreateObject("Word.Application")
End If
Err.Clear
On Error GoTo 0

oWordApp.Visible = True


'> Loop through the folder to get the word files
strFileName = Dir$(sFolder & strFilePattern)
Do Until strFileName = ""
    sFileName = sFolder & strFileName

    '> Open the word doc
    Set oWordDoc = oWordApp.Documents.Open(sFileName)
    
    Application.DisplayAlerts = False


    '> Update Fields
    oWordApp.ActiveDocument.Fields.Update
     

    '> Save and close the file
    oWordDoc.Save
    oWordDoc.Close SaveChanges:=True
    
        
    '> Find next file
    strFileName = Dir$()
Loop

'> Quit and clean up
oWordApp.Quit

Set oWordDoc = Nothing
Set oWordApp = Nothing

End Sub