ColdFusion：从内部结构获取数组 - Binance API 结果

Question

Horray - 让 ColdFusion 到 Binance API 正常工作。

Binance API 结果在 JSON 结构中有一个数组。

尝试提取填充数据。但运气并不好。

 <cfset result = '{"symbol":"SHIBUSDT","orderId":1158141049,"orderListId":-1,"clientOrderId":"tAMnbc6XLKEMNFENUdbNvD","transactTime":1645634941287,"price":"0.00000000","origQty":"784913.00","executedQty":"784913.00","cummulativeQuoteQty":"20.72170320","status":"FILLED","timeInForce":"GTC","type":"MARKET","side":"SELL","fills":[{"price":"0.00002640","qty":"784913.00","commission":"0.02072170","commissionAsset":"USDT","tradeId":291444301}]}'>

我需要的数组从填充开始，其内部结构如下：

  ,"fills":[{"price":"0.00002640","qty":"784913.00","commission":"0.02072170","commissionAsset":"USDT","tradeId":291444301}]

从这里开始，轻松显示 JSON 结果，轻松获取符号、侧面等...

 <cfscript>
   record = deserializeJSON(#result#);
   writeOutput( "<br>SYMBOL:"& record.symbol); 
   writeOutput( "<br>SIDE:"& record.side);   
 </cfscript>

有点尝试通过此方法获取填充数组数据，但没有运气。 。

 <cfoutput>
 <cfset arrayOfStructs = deserializeJson(result[fills])>
 <cfloop array="#arrayOfStructs#" index="retdata">
       <cfset Price = retdata.price />
       <cfset QTY = retdata.qty />
       #price#
          <br>#qty#
 </cfloop>
 </cfoutput>

应该是一件容易的事 也许我的大脑因我所经历的所有 API 之争而被烧伤了。

Answer 1

我能够解决。感谢您的回答。我也会看看该代码。

简单的 CFHTTP POST 到 Binance API - 用于交易（买入/卖出）

 <cfhttp url="#base_api##req_path#" method="POST" result="result" charset="utf-8">
 <cfhttpparam type="header" name="X-MBX-APIKEY" value="#bn_key#"> 
 <cfhttpparam type="body" value="#thebody#">
 </cfhttp> 

 <cfset result = #result.filecontent#>

 <cfscript>
   record = deserializeJSON(#result#);

   need = record.fills;

   writeOutput("SYMBOL:"& record.symbol); 
   writeOutput("<br>SIDE:"& record.side);  

   // writeDump(need);
   // writeDump(record);

 </cfscript>

这会获取所需的数组 [need]，其中包含实际的买入/卖出数据。然后循环播放即可。

 <cfoutput>
 <cfloop array="#need#" index="retdata">
       <cfset Price = retdata.price />
       <cfset QTY = retdata.qty />
      PRICE : #price#
    <br>Quantity : #qty#
 </cfloop>
 </cfoutput>

Answer 2

record = deserializeJSON(#result#);
..

您非常接近，但无需反序列化两次。只需使用现有的 record 变量即可。由于 result[fills] 已经是一个 CF 数组，只需循环遍历它：

<cfscript>
  result = '{"symbol":"SHIBUSDT",....}'; 

  record = deserializeJSON(result);
  writeOutput( "<br>SYMBOL:"& record.symbol); 
  writeOutput( "<br>SIDE:"& record.side);     

  for (fill in record.fills) {
    price = fill.price;
    qty = fill.qty;
    
    writeOutput("<br>price="& price &" qty="& qty);
  }
  
</cfscript>

---

更新 2/29/2022：有关错误处理的注意事项

为了简洁起见，您可能省略了 cfhttp 错误处理，但如果没有......在尝试对响应执行任何操作之前，验证 http 调用实际上是否成功（并且它包含预期的 JSON 字符串）始终是一个好习惯。否则，如果 Web 服务遇到问题，代码可能会崩溃并出现神秘错误。把它们放在一起......

<cfscript>
  // Using all cfscript for consistency   
  cfhttp(url="#base_api##req_path#" 
         , method="POST" 
         , result="result" 
         , charset="utf-8") {
     cfhttpparam( type="header", name="X-MBX-APIKEY", value="#bn_key#");
     cfhttpparam( type="body", value=theBody );
  }
  
  if (result.statusCode eq "200 OK" && IsJSON( result.fileContent )) {
     
     response = deserializeJSON( result.fileContent );
     writeOutput( "<br>SYMBOL:"& response.symbol); 
     writeOutput( "<br>SIDE:"& response.side);     

     for (fill in response.fills) {
        price = fill.price;
        qty = fill.qty;
    
        writeOutput("<br>price="& price &" qty="& qty);
     }
    
  
  }
  else {
     WriteOutput("ERROR: Houston we have a problem...");  
     writeDump( result );
  }
</cfscript>