如何检测特定的Delphi版本当前是否正在运行？

Question

在 Delphi 11 Alexandria 中 Windows 10 上的 32 位 VCL 应用程序中，我尝试检测当前是否正在运行特定的 Delphi 版本。因此，我使用 Winapi.TlHelp32.CreateToolhelp32Snapshot 函数来搜索“bds.exe”：

function ProcessExists(exeFileName: string): Boolean;
var
  ContinueLoop: Winapi.Windows.BOOL;
  FSnapshotHandle: Winapi.Windows.THandle;
  FProcessEntry32: Winapi.TlHelp32.TProcessEntry32;
begin
  FSnapshotHandle := Winapi.TlHelp32.CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  FProcessEntry32.dwSize := System.SizeOf(FProcessEntry32);
  ContinueLoop := Winapi.TlHelp32.Process32First(FSnapshotHandle, FProcessEntry32);
  Result := False;
  while Integer(ContinueLoop) <> 0 do
  begin
    if SameText(ExtractFileName(FProcessEntry32.szExeFile), ExeFileName) or SameText(FProcessEntry32.szExeFile, ExeFileName) then
    begin
      Result := True;
      CodeSite.Send('ProcessExists: FProcessEntry32.szExeFile', FProcessEntry32.szExeFile);
      BREAK;
    end;
    ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32);
  end;
  Winapi.Windows.CloseHandle(FSnapshotHandle);
end;
...
CodeSite.Send('ProcessExists(ThisBdsExe)', ProcessExists('bds.exe'));

不幸的是，FProcessEntry32.szExeFile 仅返回 FILENAME，而没有 PATH 信息。所以我只得到 Delphi 是否正在运行的信息，而不是特定 Delphi 版本是否正在运行的信息！

有没有办法从 FProcessEntry32 结构中获取 PATH 信息？

当然，我知道我的计算机上存在的每个 bds.exe 的路径。但这不起作用：

CodeSite.Send('ProcessExists(Delphi 11 bds.exe path)', ProcessExists('C:\Program Files (x86)\Embarcadero\Studio\22.0\bin\bds.exe'));

Answer 1

GetModuleFileNameEx 对我有用：

function GetPathFromPID(const PID: cardinal): string;
var
  hProcess: THandle;
  path: array[0..MAX_PATH - 1] of char;
begin
  hProcess := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, false, PID);
  if hProcess <> 0 then
  try
    if GetModuleFileNameEx(hProcess, 0, path, MAX_PATH) = 0 then
      RaiseLastOSError;
    result := path;
  finally
    CloseHandle(hProcess)
  end
  else
    RaiseLastOSError;
end;

function ProcessExists(exeFileName: string): Boolean;
var
  ContinueLoop: Winapi.Windows.BOOL;
  FSnapshotHandle: Winapi.Windows.THandle;
  FProcessEntry32: Winapi.TlHelp32.TProcessEntry32;
begin
  FSnapshotHandle := Winapi.TlHelp32.CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0);
  FProcessEntry32.dwSize := System.SizeOf(FProcessEntry32);
  ContinueLoop := Winapi.TlHelp32.Process32First(FSnapshotHandle, FProcessEntry32);
  Result := False;
  var ThisExeName := ExtractFileName(exeFileName);
  while Integer(ContinueLoop) <> 0 do
  begin
    if SameText(ExtractFileName(FProcessEntry32.szExeFile), ThisExeName) or SameText(FProcessEntry32.szExeFile, ThisExeName) then
    begin
      var ThisBdsExePath := GetPathFromPID(FProcessEntry32.th32ProcessID);
      Result := SameText(exeFileName, ThisBdsExePath);
      if Result then BREAK;
    end;
    ContinueLoop := Process32Next(FSnapshotHandle, FProcessEntry32);
  end;
  Winapi.Windows.CloseHandle(FSnapshotHandle);
end;

Answer 2

PROCESSENTRY32' 的 API 帮助s szExeFile 条目：

szExeFile

进程的可执行文件的名称。要检索完整的
可执行文件的路径，调用Module32First函数并检查
返回的 MODULEENTRY32 结构的 szExePath 成员。
但是，如果调用进程是32位进程，则必须调用
QueryFullProcessImageName 函数检索完整路径
64 位进程的可执行文件。

因此，您需要进行 Module32First 调用，并且目前至少 BDS 是 32 位进程，因此即使您的应用程序是 32 位，您也不需要使用 QueryFullProcessImageName。