在 Perl 中，如何确保字符串对应于有效日期？

Question

我想知道 Perl 中是否有一种简单的方法来确保日期字符串对应于有效日期。

例如，2012 02 30 不正确，因为它不存在。

Answer 1

DateTime 模块将在创建新对象时验证日期。

$ perl -we 'use DateTime; my $dt; 
    eval { $dt = DateTime->new( 
        year => 2012, 
        month => 2, 
        day => 30);
    }; print "Error: $@" if $@;'

错误：-e 第 1 行处的月份日期无效（日 = 30 - 月 = 2 - 年 = 2012）

它也可以在给定的 DateTime 对象上动态运行：

$dt->set(day => 30);

Answer 2

像这样使用 Class::Date 应该可以工作

perl testit.pl
日期或时间范围检查失败

use Class::Date;


my $d=Class::Date->new('2021-02-30');
unless ( $d->error ) {
  print "good date\n";
} else {
   print $d->errstr(). "\n";
}
exit;

Answer 3

检查这里：
http://www.perlmonks.org/?node_id=564594

我相信你会得到您向明智的僧侣寻求答案。

Answer 4

您可以通过使用 POSIX mktime 来完成此操作，但是显然，只有当您有足够灵活的 mktime 实现时。

我所做的就是插入数字，然后使用当地时间将它们取回，如果我取回当天的值，那么它就是一个有效的数字。因此，给定您的字符串：

my ( $y, $m, $d ) = split ' ', $date_string;
die "$date_string is not a valid date!" 
    unless ( $d == ( localtime mktime( 0, 0, 0, $d, $m - 1, $y - 1900 ))[3] )
    ; 

看，在我习惯的 mktime 版本中， mktime( 0, 0, 0, 30, 1, 112 ) 会'2012-03-01' 和 30 != 1

Answer 5

您还可以使用 Time::Local：

#!/usr/bin/env perl

use strict; use warnings;
use Carp qw( croak );
use Time::Local qw( timegm );

my @to_check = ('1927 06 18', '2012 02 30');

for my $date ( @to_check ) {
    printf "'%s' is %s\n", $date, check_date($date) ? 'valid' : 'invalid';
}

sub check_date {
    my ($date) = @_;

    my ($year, $month, $mday) = split ' ', $date;

    my $ret;

    eval {
        $ret = timegm(0, 0, 0, $mday, $month - 1, $year - 1900);
    };

    return $ret && $ret;
}

Answer 6

也许这也会有帮助：

use Time::Piece; #in perl CORE distro since 5.10
use 5.010;
say Time::Piece->strptime("2011-02-29","%Y-%m-%d")->strftime("%Y-%m-%d");
#2011-03-01
say Time::Piece->strptime("2012-02-29","%Y-%m-%d")->strftime("%Y-%m-%d");
#2012-02-29