将多个 CSV 转换为 xls 或 xlsx 并对其应用格式

Question

我有一个很大的 Excel 文件，用于聚合多个客户端的问题跟踪，我需要根据客户端将其分成更小的文件。

到目前为止，我已经得到了以下内容：我构建了一个 python 脚本，该脚本将文件划分为适当的特定于客户端的文件，并将正确的标题行应用于所有文件，但它生成的 CSV 是很丑。我的老板想要应用一些格式，所以我需要做的是（对于目录中的所有 CSV）：

1. 将每个文件从 CSV 转换为 .xls（或 .xlsx），以便它将保留格式

2. 自动调整列宽度

3. 将第一行设为粗体（并且可能应用颜色）到row)

到目前为止，我猜我可以使用 pyWin32 或 pyExcelerator，但考虑如何我的改变最小想要制作一个 VB 脚本或宏或其他东西可能更容易做到这一点，但我真的不知道这些工具。

Answer 1

最简单的方法是使用 VBA

这是一个快速宏，用于循环打开 csv 的文件夹，应用自动调整并另存为 .xlsx

注意：

1. 它使用早期绑定，因此需要对脚本运行时的引用。如果您愿意，可以轻松更改为后期绑定。
2. 为了清楚起见，我省略了错误处理和各种速度优化。它是否足够安全或足够快将取决于您的预期用途以及文件的数量和大小。

---

Sub FormatCSVs()
    Dim fso As FileSystemObject
    Dim pth As String
    Dim fl As File
    Dim wb As Workbook
    
    Set fso = New FileSystemObject
    pth = "C:\Test" ' <-- replace with your path, or add a folder selection dialog>
    For Each fl In fso.GetFolder(pth).Files
       If StrComp(fso.GetExtensionName(fl.Path), "csv", vbTextCompare) = 0 Then
            Set wb = Workbooks.Open(fl.Path)
            With wb.Sheets(1)
                .UsedRange.EntireColumn.AutoFit
                .Rows(1).Font.Bold = True
                .Rows(1).Interior.ColorIndex = 3
            End With
            wb.SaveAs pth & "\" & fso.GetBaseName(fl.Path), xlOpenXMLWorkbook
               ' or use xlExcel8 for .xls
            wb.Close
        End If
    Next
    
    Set fl = Nothing
    Set fso = Nothing
End Sub