相对于包含模式的行，删除前面的 n1 行和后面的 n2 行

Question

sed -e '/XXXX/,+4d' fv.out

我必须在文件中找到特定模式并同时删除其上方 5 行和下方 4 行。我发现上面的行删除了包含图案的行及其下面的四行。

sed -e '/XXXX/,~5d' fv.out

在 sed 手册中，给出 ~ 代表模式后面的行。但当我尝试时，删除的是模式后面的行。

那么，如何同时删除包含该模式的行上方 5 行和下方 4 行呢？

Answer 1

使用 sed 的一种方法，假设模式彼此不够接近：

script.sed 的内容：

## If line doesn't match the pattern...
/pattern/ ! { 

    ## Append line to 'hold space'.
    H   

    ## Copy content of 'hold space' to 'pattern space' to work with it.
    g   

    ## If there are more than 5 lines saved, print and remove the first
    ## one. It's like a FIFO.
    /\(\n[^\n]*\)\{6\}/ {

        ## Delete the first '\n' automatically added by previous 'H' command.
        s/^\n//
        ## Print until first '\n'.
        P   
        ## Delete data printed just before.
        s/[^\n]*//
        ## Save updated content to 'hold space'.
        h   
    } 

### Added to fix an error pointed out by potong in comments.
### =======================================================
    ## If last line, print lines left in 'hold space'.
    $ { 
        x   
        s/^\n//
        p   
    } 
### =======================================================


    ## Read next line.
    b   
}

## If line matches the pattern...
/pattern/ {

    ## Remove all content of 'hold space'. It has the five previous
    ## lines, which won't be printed.
    x   
    s/^.*$//
    x   

    ## Read next four lines and append them to 'pattern space'.
    N ; N ; N ; N 

    ## Delete all.
    s/^.*$//
}

运行如下：

sed -nf script.sed infile

Answer 2

使用awk的解决方案：

awk '$0 ~ "XXXX" { lines2del = 5; nlines = 0; }
     nlines == 5 { print lines[NR%5]; nlines-- }
     lines2del == 0 { lines[NR%5] = $0; nlines++ }
     lines2del > 0 { lines2del-- }
     END { while (nlines-- > 0)  { print lines[(NR - nlines) % 5] } }' fv.out

更新：

这是解释的脚本：

• 我记得数组lines中的最后5行使用旋转索引(NR% 5；NR 是记录编号；在本例中为行）。
• 如果我在当前行中找到模式（$0 ~ "XXXX; $0 是当前记录：在本例中是一行；并且 ~作为扩展正则表达式匹配运算符），我重置了读取的行数，并注意到我有 5 行要删除（包括当前行），
• 如果我已经读取了 5 行，我会打印当前行。 ）
• 如果我没有要删除的行（这也是如此 如果我读了 5 行，我会将当前行放入缓冲区并增加行数，请注意如果打印了一行
• ， 则行数如何减少然后增加。任何内容并减少要删除的行数。
• 在脚本末尾，我打印了数组中的所有行。

我的脚本原始版本如下，但我最终将其优化为上述版本：

awk '$0 ~ "XXXX" { lines2del = 5; nlines = 0; }
     lines2del == 0 && nlines == 5 { print lines[NR%5]; lines[NR%5] }
     lines2del == 0 && nlines < 5 { lines[NR%5] = $0; nlines++ }
     lines2del > 0 { lines2del-- }
     END { while (nlines-- > 0)  { print lines[(NR - nlines) % 5] } }' fv.out

< code>awk 是一个很棒的工具我强烈建议您在网上找到一个教程并阅读它：awk 可与扩展正则表达式 (ERE) 配合使用。 。它们的语法与 sed 中使用的标准正则表达式 (RE) 略有不同，但是使用 RE 可以完成的所有操作都可以使用埃雷。

Answer 3

这个想法是读取 5 行而不打印它们。如果找到该图案，请删除未打印的行和下面的 4 行。如果没有找到该模式，请记住当前行并打印第一个未打印的行。最后，打印未打印的内容。

sed -n -e '/XXXX/,+4{x;s/.*//;x;d}' -e '1,5H' -e '6,${H;g;s/\n//;P;s/[^\n]*//;h}' -e '${g;s/\n//;p;d}' fv.out

当然，这仅当您的模式在文件中出现一次时才有效。如果你有很多，你需要在找到你的模式后阅读 5 行新的行，如果你在这些行中再次有你的模式，事情就会变得复杂。在这种情况下，我认为 sed 不是正确的工具。

Answer 4

这可能对你有用：

sed 'H;$!d;g;s/\([^\n]*\n\)\{5\}[^\n]*PATTERN\([^\n]*\n\)\{5\}//g;s/.//' file

或者这个：

awk --posix -vORS='' -vRS='([^\n]*\n){5}[^\n]*PATTERN([^\n]*\n){5}' 1 file

一个更有效的 sed 解决方案：

sed ':a;/PATTERN/,+4d;/\([^\n]*\n\)\{5\}/{P;D};$q;N;ba' file

Answer 5

如果您愿意将结果输出到文件而不是 stdout，vim 可以非常有效地完成它：

vim -c 'g/pattern/-5,+4d' -c 'w! outfile|q!' infile

或者

vim -c 'g/pattern/-5,+4d' -c 'x' infile

就地编辑文件。