SQL Server 中的字符串连接

Question

考虑这样一种情况，我们在 SQL Server 2005 的 SP 中有两个变量，如下所示，

@string1 = 'a,b,c,d'
@string2 = 'c,d,e,f,g'

是否有解决方案可以从中获取新字符串（如 (@string1 U @string2) ）而不使用任何循环。即最终的字符串应该是这样的，

@string3 = 'a,b,c,d,e,f,g'

Answer 1

如果您需要一组而不是一次一行地执行此操作。给定以下 split 函数：

USE tempdb;
GO
CREATE FUNCTION dbo.SplitStrings(@List nvarchar(max))
RETURNS TABLE
AS
   RETURN ( SELECT Item FROM
       ( SELECT Item = x.i.value(N'./text()[1]', N'nvarchar(max)')
         FROM ( SELECT [XML] = CONVERT(xml, '<i>'
         + REPLACE(@List,',', '</i><i>') + '</i>').query('.')
           ) AS a CROSS APPLY [XML].nodes('i') AS x(i) ) AS y
       WHERE Item IS NOT NULL
   );
GO

然后使用下表和示例数据以及字符串变量，您可以通过这种方式获得所有结果：

DECLARE @foo TABLE(ID INT IDENTITY(1,1), col NVARCHAR(MAX));

INSERT @foo(col) SELECT N'c,d,e,f,g';
INSERT @foo(col) SELECT N'c,e,b';
INSERT @foo(col) SELECT N'd,e,f,x,a,e';

DECLARE @string NVARCHAR(MAX) = N'a,b,c,d';

;WITH x AS
(
    SELECT f.ID, c.Item FROM @foo AS f
    CROSS APPLY dbo.SplitStrings(f.col) AS c
), y AS
(
    SELECT ID, Item FROM x
    UNION
    SELECT x.ID, s.Item
        FROM dbo.SplitStrings(@string) AS s
        CROSS JOIN x
)
SELECT ID, Items = STUFF((SELECT ',' + Item 
    FROM y AS y2 WHERE y2.ID = y.ID 
    FOR XML PATH(''), TYPE).value(N'./text()[1]', N'nvarchar(max)'), 1, 1, N'')
FROM y
GROUP BY ID;

结果：

ID   Items
--   ----------
 1   a,b,c,d,e,f,g
 2   a,b,c,d,e
 3   a,b,c,d,e,f,x

在较新的版本 (SQL Server 2017+) 上，查询要简单得多，并且您不需要不需要创建您自己的自定义字符串分割函数：

;WITH x AS
(
    SELECT f.ID, c.value FROM @foo AS f
    CROSS APPLY STRING_SPLIT
    (
      CONCAT(f.col, N',', @string), N','
    ) AS c GROUP BY f.ID, c.value
)
SELECT ID, STRING_AGG(value, N',')
WITHIN GROUP (ORDER BY value)
FROM x GROUP BY ID;

• 示例 db>>fiddle

现在，您真正应该做的是遵循前面的内容建议并首先将这些内容存储在相关表中。每当发生插入或更新时，您可以使用相同类型的拆分方法来单独存储字符串，而不是仅仅将 CSV 转储到单个列中，并且您的应用程序实际上不必更改将数据传递到的方式你的程序。但取出数据肯定会更容易！

编辑

为 SQL Server 2008 添加一个潜在的解决方案，该解决方案稍微复杂一些，但只需少一个循环即可完成工作（使用大量表扫描和替换）。我不认为这比上面的解决方案更好，而且它的可维护性肯定较差，但如果您发现自己能够升级到 2008 或更高版本（也适用于任何 2008+ 用户），那么它是一个可以测试的选项。遇到这个问题）。

SET NOCOUNT ON;

-- let's pretend this is our static table:

CREATE TABLE #x
(
    ID int IDENTITY(1,1),
    col nvarchar(max)
);

INSERT #x(col) VALUES(N'c,d,e,f,g'), (N'c,e,b'), (N'd,e,f,x,a,e');

-- and here is our parameter:

DECLARE @string nvarchar(max) = N'a,b,c,d';

代码：

DECLARE @sql nvarchar(max) = N'DECLARE @src TABLE(ID INT, col NVARCHAR(32));
    DECLARE @dest TABLE(ID int, col nvarchar(32));';

SELECT @sql += '
    INSERT @src VALUES(' + RTRIM(ID) + ','''
    + REPLACE(col, ',', '''),(' + RTRIM(ID) + ',''') + ''');'
FROM #x;

SELECT @sql += '
    INSERT @dest VALUES(' + RTRIM(ID) + ','''
    + REPLACE(@string, ',', '''),(' + RTRIM(ID) + ',''') + ''');'
FROM #x;

SELECT @sql += '
    WITH x AS (SELECT ID, col FROM @src UNION SELECT ID, col FROM @dest)
    SELECT DISTINCT ID, Items = STUFF((SELECT '','' + col
     FROM x AS x2 WHERE x2.ID = x.ID FOR XML PATH('''')), 1, 1, N'''')
     FROM x;'

EXEC sys.sp_executesql @sql;
GO
DROP TABLE #x;

这在 2005 年要做起来要困难得多（尽管并非不可能），因为您需要将 VALUES() 子句更改为 UNION ALL...

Answer 2

有两种方法可以做到这一点：

• 构建一个 CLR 函数来为您完成这项工作。将逻辑移回 .NET 代码，这是更容易进行字符串操作的平台。

• 如果您必须使用 SQL Server，那么您将需要：

将两个字符串“分解”为两个表，此函数可能会有所帮助： http://blog.logiclabz.com/sql-server/split-function-in-sql-server-to-break-comma-separated-strings-into-table.aspx

获取两个表中的唯一字符串列表。 （简单查询）

将两个字符串表“内爆”到一个变量中（http://stackoverflow.com/questions/194852/concatenate-many-rows-into-a-single-text-string）

Answer 3

找到此函数 dbo 相关答案中的.Split，您可以像这样使用this：

declare @string1 nvarchar(50) = 'a,b,c,d'
declare @string2 nvarchar(50) = 'c,d,e,f,g'

select * from dbo.split(@string1, ',')

select * from dbo.split(@string2, ',')

declare @data nvarchar(100) = ''

select @data =  @data +  ',' + Data from (
    select Data from dbo.split(@string1, ',')
    union
    select Data from dbo.split(@string2, ',')
) as d

select substring(@data, 2, LEN(@data))

最后一个 SELECT 返回

a,b,c,d,e,f,g

Answer 4

抱歉

set @string3 = @string1+','+@string2

，不清楚您只想要独特的事件。您使用什么版本的 SQL Server？字符串操作函数因版本而异。

如果您不介意 UDF 分割字符串，请尝试以下操作：

CREATE FUNCTION dbo.Split
(
    @RowData nvarchar(2000),
    @SplitOn nvarchar(5)
)  
RETURNS @RtnValue table 
(
    Id int identity(1,1),
    Data nvarchar(100)
) 
AS  
BEGIN 
    Declare @Cnt int
    declare @data varchar(100)
    Set @Cnt = 1

    While (Charindex(@SplitOn,@RowData)>0)
    Begin
       Insert Into @RtnValue (data) 
     Select ltrim(rtrim(Substring(@RowData,1,Charindex(@SplitOn,@RowData)-1)))
             Set @RowData = Substring(@RowData,Charindex(@SplitOn,@RowData)+1,len(@RowData))
         Set @Cnt = @Cnt + 1
    End

    Insert Into @RtnValue (data)
    Select Data = ltrim(rtrim(@RowData))


    Return
END

以及使用 UDF 的代码

go
@string1 = 'a,b,c,d'
@string2 = 'c,d,e,f,g'

declare @string3 varchar(200)
set @string3 = ''
select @string3 = @string3+data+',' 
from ( select data,min(id) as Id from dbo.split(@string1+','+@string2,',') 
     group by data ) xx
order by xx.id

print left(@string3,len(@string3)-1)

Answer 5

下面的 SQL 函数会将逗号分隔的列表转换为表变量...

CREATE FUNCTION [dbo].[udfCsvToTable]( @CsvString VARCHAR( 8000))
-- Converts a comman separated value into a table variable

RETURNS @tbl TABLE( [Value] VARCHAR( 100) COLLATE DATABASE_DEFAULT NOT NULL)

AS BEGIN

DECLARE @Text VARCHAR( 100)

SET @CsvString = RTRIM( LTRIM( @CsvString))
SET @CsvString = REPLACE( @CsvString, CHAR( 9), '')
SET @CsvString = REPLACE( @CsvString, CHAR( 10), '')
SET @CsvString = REPLACE( @CsvString, CHAR( 13), '')

IF LEN( @CsvString) < 1 RETURN

WHILE LEN( @CsvString) > 0 BEGIN

    IF CHARINDEX( ',', @CsvString) > 0 BEGIN

        SET @Text = LEFT( @CsvString, CHARINDEX( ',', @CsvString) - 1)
        SET @CsvString = LTRIM( RTRIM( RIGHT( @CsvString, LEN( @CsvString) - CHARINDEX( ',', @CsvString))))
    END
    ELSE BEGIN

        SET @Text = @CsvString
        SET @CsvString = ''
    END

    INSERT @tbl VALUES( LTRIM( RTRIM( @Text)))
END

RETURN
END

然后您可以将两个表合并在一起，就像这样...

SELECT * FROM udfCsvToTable('a,b,c,d')
UNION   
SELECT * FROM udfCsvToTable('c,d,e,f,g')

这将为您提供一个结果集

：
乙
c
d
e
f
克