Delphi 内存复制与记录到另一个记录

Question

我的逻辑有问题。我不知道如何在 Delphi 中将记录复制到另一条记录。

TypeA = record
  value1 : word;
  value2 : word;
  value3 : word;
  end;

TypeB = record
  b1 : byte;
  b2 : byte;    
  end;

我有两条记录 TypeA 和 TypeB。例如，我发现TypeA记录中的数据属于TypeB记录。 注意：TypeA 的数据长度较长。

问题：如何复制 TypeA 内存并将其放入 TypeB 记录中？

CopyMemory(@TypeA, @TypeB, Length(TypeB))

当我尝试 CopyMemory 并收到错误（不兼容）类型）。

PS：我不想像下面这样复制或分配它。

TypeB.b1 := TypeA.value1 && $FF;

TypeA 和 TypeB 只是示例记录。大多数情况下，记录TypeA和TypeB可能包含多个记录，并且它 分配表单 TypeA 并分配给 TypeB 记录会更困难。

提前致谢

----补充问题：

有没有办法将Delphi记录复制到字节数组，如何？如果有，

• TypeA 记录到 Byte Array
• Byte Array 到 Type B

这个逻辑行得通吗？

Answer 1

CopyMemory(@a, @b, SizeOf(TypeB))

如果 a 的类型为 TypeA，而 b 的类型为 TypeB。

Answer 2

变体记录：

TypeA = packed record
  value1 : word;
  value2 : word;
  value3 : word;
  end;

TypeB = packed record
  b1 : byte;
  b2 : byte;
  end;

TypeAB = packed record
  case boolean of
    false:(a:TypeA);
    true:(b:TypeB);
end;
..
..
var someRec:TypeAB;
    anotherRec:TypeAB;
..
..
  anotherRec.b:=someRec.b

Answer 3

procedure CopyAtoB( const A: TypeA; var B: TypeB);
begin
// Assume A is bigger than B.
Move( A, B, SizeOf( TypeB))
end;

或（带数学单位）

procedure CopyAtoB( const A: TypeA; var B: TypeB);
begin
// No assumptions about A, B sizes.
FillChar( B, SizeOf( B), 0);
Move( A, B, Min( SizeOf( TypeA), SizeOf( TypeB)))
end;

Answer 4

将A记录复制到B记录有一个好方法——运算符重载；在这种情况下，您可以简单地重载隐式和显式操作并编写类似 b := a 的代码：

program Project1;
{$APPTYPE CONSOLE}
{$R *.res}
uses System.SysUtils;

type
    TTypeA = record
      value1 : integer;
      value2 : integer;
      value3 : integer;
    end;

    TTypeB = record
      b1 : byte;
      b2 : byte;
      class operator Implicit(value : TTypeA):TTypeB;
    end;

class operator TTypeB.Implicit(value: TTypeA): TTypeB;
begin
    result.b1 := Hi(value.value1);
    result.b2 := Lo(value.value1);
end;


var a : TTypeA;
    b : TTypeB;
begin
    b := a;
end.

您可以使用 TBytesStream 将记录复制到字节数组：

var a : TTypeA;
    bs : TBytesStream;
    bArr : TArray<byte>;//array of byte;
begin
    bs := TBytesStream.Create();
    bs.Write(a, sizeof(a));
    bArr := bs.Bytes;
end;

或者简单地将字节数组的大小设置为 sizeof (A)，然后复制内存

Answer 5

所有其他答案都是直接复制内存的变体，但我认为这是错误的方法。它是低级的，并且您使用的是高级语言，很容易犯错误，而且它如果您的记录包含托管数据类型，则存在风险。

如果您尝试获取记录的一个元素的前两个字节，请尝试使用变体记录（在 C 中为联合）。它是记录的一部分，可以通过多个地址进行寻址。方式，在这里你想将其作为一个字或一系列字节来寻址。

尝试这样的事情（未经测试，只是在 SO 编辑器中输入）：

type
  TTwoBytes : packed record
    ByteA, ByteB : Byte;
  end;

  TValueRecord : packed record:
    case Boolean of
      True: (Value: SmallInt);
      False: (ValueBytes : TTwoBytes);
    end;
  end;

  TMyRecord = packed record
    Value1, Value2, Value3 : TValueRecord;
  end;

然后对于代码：

var
  MyRecord: TMyRecord;
  MyBytes: TTwoBytes;
begin
  MyRecord := ...; // Fill it with data here
  // Access the words / smallints by something like: MyRecord.Value1.Value
  MyBytes := MyRecord.ValueBytes; // The key bit: type safe assignment
  // Do something with MyBytes.ByteA or MyBytes.ByteB
end;

这比直接复制内存给你带来了什么更好？

• 它是安全的：如果你有包含字符串的更复杂的记录，接口等，它仍然可以工作而不会破坏引用计数。
• 它是类型安全的：不直接复制内存：您和编译器都知道您拥有和正在使用什么。
• 这是规范的：这可能是“德尔福方式”。 （虽然有多种方法来构建记录 - 如果你查看答案历史记录，我最初有一个更糟糕的方法。而且我认为 'case ... of' 语法很愚蠢，但是这是另一个讨论...:))

一些注意事项：

• 我将您的 Word 更改为 SmallInt ，因为我找到了 Word令人困惑 - 它实际上不是机器的“字长”， 它是 16 位。
• 另外，我认为这是一篇关于变体记录的好文章。
• 我使用了“打包记录”，这是理由这是...不确定。

Answer 6

您可以通过以下方式省略 CopyMemory()（Windows 单元）的使用：

type
  PTypeA = ^TTypeA;
  TTypeA = record
    value1 : word;
    value2 : word;
    value3 : word;
  end;
  PTypeB = ^TTypeB;
  TTypeB = record
    b1 : byte;
    b2 : byte;
  end;
var
  A: TTypeA = (value1 : 11; value2 : 22; value3 : 33);
  B: TTypeB;
  B1: TTypeB;
  C: {packed?} array of Byte;
begin
  Assert(SizeOf(TTypeA) >= SizeOf(TTypeB));
  //...
  B:= PTypeB(@A)^;
  //...
  SetLength(C, SizeOf(A));
  // TTypeA record to Byte Array
  PTypeA(@C[0])^:= A;
  // Byte Array to TTypeB
  B1:= PTypeB(@C[0])^
end;

Answer 7

如果您只想将字节从一个位置复制到另一个位置，请使用 MOVE 而不是 CopyMemory。

要获取记录的大小，请使用 SizeOf 而不是 Length。