带中断的 Xslt 嵌套 For 循环

Question

总之，

我是 XSLT 的新手，面临着一个典型的问题。下面是问题详细信息

根据下面的数据，我仅当 ItemA/ANum 元素属于 AName BBC 而不是 ItemB/tempBNum 的一部分时才需要显示 ItemA/ANum 元素，

因此以下数据的所需结果应该是 0214,BBC，因为它是ItemA，也是一个BBC，没有出现在ItemB中。

<myData>
<ItemA>
    <ANum>0213</ANum>
    <AName>OOC</AName>
</ItemA>
<ItemA>
    <ANum>0031</ANum>
    <AName>BBC</AName>
</ItemA>
<ItemA>
    <ANum>0214</ANum>
    <AName>BBC</AName>
</ItemA>
<ItemA>
    <ANum>0044</ANum>
    <AName>BBC</AName>
</ItemA>

<ItemB>
    <tempBNum>0031</tempBNum>
</ItemB>
<ItemB>
    <tempBNum>0044</tempBNum>
</ItemB>
</myData>

为此，我尝试放入嵌套 For 循环的逻辑，唯一的问题是当 ItemAObj/ANum = tempBNum 时嵌套循环应该中断，但它不会中断并产生重复的结果。

  <xsl:for-each select="myData/ItemA">
    <xsl:variable name="ItemAObj" select="." />
    Num = <xsl:value-of select="$ItemAObj/ANum"/>
    <xsl:for-each select="/myData/ItemB">
    <xsl:choose>
        <xsl:when test="$ItemAObj/ANum!=tempBNum and $ItemAObj/AName='BBC'"> <xsl:value-of select="tempBNum"/>
        <xsl:text> </xsl:text>
    </xsl:when>
        </xsl:choose>
        </xsl:for-each>
  </xsl:for-each>

对此的任何帮助将不胜感激。

Answer 1

您不需要使用任何 xsl:for-each 来解决问题，更不需要嵌套 xsl:for-each.

事实上，可以使用单个 XPath 表达式来选择所需的 ItemA 元素：

/*/ItemA[AName = 'BBC' 
       and 
         not(ANum = /*/ItemB/tempBNum)
        ]

因此，计算上述 XPath 表达式并将结果复制到输出的简单 XSLT 转换为：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     "/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)]"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<myData>
    <ItemA>
        <ANum>0213</ANum>
        <AName>OOC</AName>
    </ItemA>
    <ItemA>
        <ANum>0031</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemA>
        <ANum>0214</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemA>
        <ANum>0044</ANum>
        <AName>BBC</AName>
    </ItemA>
    <ItemB>
        <tempBNum>0031</tempBNum>
    </ItemB>
    <ItemB>
        <tempBNum>0044</tempBNum>
    </ItemB>
</myData>

生成所需的正确结果：

<ItemA>
   <ANum>0214</ANum>
   <AName>BBC</AName>
</ItemA>

如果我们只需要文本节点的值，只需使用 string()函数：

string(/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)])

那么修改后的变换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:copy-of select=
     "string(/*/ItemA[AName = 'BBC' and not(ANum = /*/ItemB/tempBNum)])"/>
 </xsl:template>
</xsl:stylesheet>

当应用于同一个 XML 文档（上面），会产生：

    0214
    BBC

注意：如果性能开始变得重要，那么下一步可能会使用键来提高转换效率。

Answer 2

您无法中断，但可以添加条件以确保没有 previous-sibling ItemAObj/ANum = tempBNum

Answer 3

这可以通过一种不同的方式来实现，需要 for-each 迭代项目并依次检查它。相反，您可以使用键来查找某个数字是否存在 ItemB 元素

<xsl:key name="itemB" match="ItemB" use="tempBNum" />

然后您可以简单地匹配不存在 ItemB< 的 itemA 元素ANNum 中出现的 /strong> 元素

<xsl:apply-templates select="ItemA[AName='BBC'][not(key('itemB', ANum))]" />

这是完整的 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>
   <xsl:key name="itemB" match="ItemB" use="tempBNum" />

   <xsl:template match="/myData">
      <xsl:apply-templates select="ItemA[AName='BBC'][not(key('itemB', ANum))]" />
   </xsl:template>

   <xsl:template match="@*|node()">
      <xsl:copy>
         <xsl:apply-templates select="@*|node()"/>
      </xsl:copy>
   </xsl:template>
</xsl:stylesheet>

当应用于示例 XML 时，输出如下：

<ItemA>
   <ANum>0214</ANum>
   <AName>BBC</AName>
</ItemA>