Xslt提取属性并生成html

Question

我正在尝试将以下 XML.. 转换

<?xml version="1.0" encoding="utf-16"?><Member TextRank="unknown" FullName="My Name" ..etc.. />

为类似以下内容，

<div class="member">
    <span class="label">
        Text Rank (note: i want to override the labels in the xslt)
    </div>
    <span class="value">
        unknown
    </span>
    <span class="label">
        Full Name
    </div>
    <span class="value">
        My Name
    </span>
    ..etc..
</div>

如果可能的话，我如何使用 xslt 来完成此操作？

Answer 1

这是一种不同的方法，它消除了对 xsl:choose 元素的需要。相反，您可以利用匹配模板为您想要覆盖的属性名称的情况提供特定模板，并为其他情况提供通用模板。

为了避免重复代码，您还可以使通用模板成为命名模板，并使用参数来覆盖名称。

<xsl:template match="@*" name="attribute">
   <xsl:param name="label" select="local-name()" />

因此，大多数属性的默认值是使用属性名称，但特定模板为 @FullName< /strong> 然后可以用不同的名称来调用它。

<xsl:template match="@FullName">
   <xsl:call-template name="attribute">
      <xsl:with-param name="label" select="'Full Name'" />
   </xsl:call-template>
</xsl:template>

以下是完整的 XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes"/>

   <xsl:template match="*">
      <div class="{local-name()}">
         <div> Title: </div>
         <xsl:apply-templates select="@*"/>
      </div>
   </xsl:template>

   <xsl:template match="@FullName">
      <xsl:call-template name="attribute">
         <xsl:with-param name="label" select="'Full Name'" />
      </xsl:call-template>
   </xsl:template>

   <xsl:template match="@*" name="attribute">
      <xsl:param name="label" select="local-name()" />
      <span class="label">
         <xsl:value-of select="concat($label, ' : ')"/>
      </span>
      <span class="value">
         <xsl:value-of select="."/>
      </span>
      <br/>
   </xsl:template>
</xsl:stylesheet>

当应用于以下 XML 时：

<Member TextRank="unknown" ID="12" FullName="My Name" Dob="01/01/1970" />

输出如下：

<div class="Member">
   <div> Title: </div>
   <span class="label">TextRank : </span>
   <span class="value">unknown</span>
   <br>
   <span class="label">ID : </span>
   <span class="value">12</span>
   <br>
   <span class="label">Full Name : </span>
   <span class="value">My Name</span>
   <br>
   <span class="label">Dob : </span>
   <span class="value">01/01/1970</span>
   <br>
</div>

Answer 2

这是我想出的解决方案。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     version="1.0">
    <xsl:output indent="yes" />
    <xsl:template match="*">
        <xsl:element name="div">
            <xsl:attribute name="class">className</xsl:attribute>
            <div>
                Title:
            </div>

            <!-- UID, Name, DBO-->
            <xsl:apply-templates select="@ID"/>
            <xsl:apply-templates select="@FullName"/>
            <xsl:apply-templates select="@Dob"/>

        </xsl:element>

    </xsl:template>

    <xsl:template match="@*">
        <xsl:element name="span">

            <xsl:attribute name="class">label</xsl:attribute>
            <xsl:choose>
                <xsl:when test="name() = 'FullName'">
                    Full Name
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="name()"/>
                </xsl:otherwise>
            </xsl:choose>
            :
        </xsl:element>
        <xsl:element name="span">
            <xsl:attribute name="class">value</xsl:attribute>
            <xsl:value-of select="."/>
        </xsl:element>
        <br/>
    </xsl:template>

</xsl:stylesheet>